cleaning up drawings to create xref

[FIFTHTEXAS]

Hi

can anyone tell me the best way to creat an x-ref from say an architects drawing, ie to grey it ot so as place a building services drawing, ie clean the drawing up as a good base plan.

usually takes ages going through changing layers to grey, then lots of blocks that dont change to grey therefore have to go in either xplode then or block editor , can someone point me in the right direction so to make it easy, are there easy options available

 

thanks

[SLW210]

Does 2008 have Xref Fade Control, if not upgrade.

[designerstuart]

it should be pretty fast to select all layers - change to grey - only a few clicks?

also if you lock the layer the xref is on, helps to appear dimmer (for drafting only, prints come out the same)

 

i don't know how to sort out the objects which are coloured by entity. bummer.

[designerstuart]

Does 2008 have Xref Fade Control, if not upgrade.

no, nor does 2009.

plus, that's just a drafting thing, right? i reckon op wants to print grey, too.

[FIFTHTEXAS]

HI

recieving drawings through with lots of layers on and colours, i want to keep the layers all i require is to change them all to grey, however going into layer manager selecting all and changing all layers to grey colours helps, however stiil the drawing has lots of blocks in it that wont change, so i either have to go into block editor do it that way or xplode the blocks, this is time consuming just wondering if there is a quicker way of doing it?

thanks

[SLW210]

HI

recieving drawings through with lots of layers on and colours, i want to keep the layers all i require is to change them all to grey, however going into layer manager selecting all and changing all layers to grey colours helps, however stiil the drawing has lots of blocks in it that wont change, so i either have to go into block editor do it that way or xplode the blocks, this is time consuming just wondering if there is a quicker way of doing it?

thanks

 

I see what you want now.

You need to search for a LISP to set all blocks to Layer "0" and ByLayer.

[FIFTHTEXAS]

Thanks for the help

[Tommy78]

Look in the lisp forum fror xcol.lsp, this script will make it very easy to set all the architecture xrefs in grey with a couple of clicks.

If the architects don't put their walls and blocks BYLAYER, go pay them a visit and beat them with a stick!

[tzframpton]

This is my setup I created. Two files:

 

• Script file
  
• LISP routine
  

Make sure the LISP routine is loaded into the drawing. I have this file in my ACADDOC.LSP file so it always loads. All the LISP routine does is sort of automate the SETBYLAYER command.

 

If you type SCR and open the Script file, it'll run through and set everything to a color of 253. It sets all things like doors, glazing, stairs, etc to color 190 through wildcard matching the layer names, and this color 190 matches a thinner linetype in my CTB file. Then it runs through the SETBYLAYER LISP routine to set all blocks and nested blocks to ByLayer. This is a very quick and easy way I use to set up architectural backgrounds. Oh and I use the LAYDEL command first to get everything I need out of the drawing quickly. Hope this helps.

 

*EDIT* Oh and feel free to use this however you want to fit your own standards.

BACKGOUND.scr

VMI-SETBYLAYER.LSP

[alanjt]

Here's a quickie I did the other day to set the color for everything within an XRef.

 

(defun c:XCC (/ xrefs lst color name)
 ;; XRef Color Change (change color of objects in selected XRef(s)
 ;; Required subroutines: AT:ListSelect
 ;; Alan J. Thompson, 02.09.11
 (vlax-for x (vla-get-blocks
               (cond (*AcadDoc*)
                     ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
               )
             )
   (if (eq (vla-get-isXRef x) :vlax-true)
     (setq xrefs (cons (strcase (strcat (vla-get-name x) "|*")) xrefs))
   )
 )

 (cond ((not (setq xrefs (vl-sort xrefs (function <)))) (alert "No XRefs in drawing"))
       ((and (setq lst (AT:ListSelect "Select XRef(s) to change: " "" 10 10 "true" xrefs))
             (setq color (acad_colordlg 1 nil))
        )
        (vlax-for x (vla-get-layers *AcadDoc*)
          (setq name (strcase (vla-get-name x)))
          (if (vl-some (function (lambda (xref) (wcmatch name xref))) lst)
            (vla-put-color x color)
          )
        )
       )
 )
 (princ)
)

(defun AT:ListSelect (title label height width multi lst / fn fo d item f)
 ;; List Select Dialog (Temp DCL list box selection, based on provided list)
 ;; title - list box title
 ;; label - label for list box
 ;; height - height of box
 ;; width - width of box
 ;; multi - selection method ["true": multiple, "false": single]
 ;; lst - list of strings to place in list box
 ;; Alan J. Thompson, 09.23.08 / 05.17.10 (rewrite)
 (setq fo (open (setq fn (vl-filename-mktemp "" "" ".dcl")) "w"))
 (foreach x (list (strcat "list_select : dialog { label = \"" title "\"; spacer;")
                  (strcat ": list_box { label = \"" label "\";" "key = \"lst\";")
                  (strcat "allow_accept = true; height = " (vl-princ-to-string height) ";")
                  (strcat "width = " (vl-princ-to-string width) ";")
                  (strcat "multiple_select = " multi "; } spacer; ok_cancel; }")
            )
   (write-line x fo)
 )
 (close fo)
 (new_dialog "list_select" (setq d (load_dialog fn)))
 (start_list "lst")
 (mapcar (function add_list) lst)
 (end_list)
 (setq item (set_tile "lst" "0"))
 (action_tile "lst" "(setq item $value)")
 (setq f (start_dialog))
 (unload_dialog d)
 (vl-file-delete fn)
 (if (= f 1)
   ((lambda (s / i s l)
      (while (setq i (vl-string-search " " s))
        (setq l (cons (nth (atoi (substr s 1 i)) lst) l))
        (setq s (substr s (+ 2 i)))
      )
      (reverse (cons (nth (atoi s) lst) l))
    )
     item
   )
 )
)

[Tommy78]

The lisp i use one a daily basis (xcol) was also by Alanjt ofcourse, credit where credit's due!

[Sittingbull]

To use the lisp program:

 

Put it in one of the supported folders. Those are defined in options --> File tab.

Use one of the existants or create one of your own.

In tools menu, go to load application.

 

Regards,

 

SB

[paul1966]

here's what i do, all of this is probably not necessary but i like a really clean xref.

i open the drawing i am using as xref, swich off layers i do not need eg flooring, i do HVAC layouts so anyhing like shelving units, room sets just make the drawing messy, i also delete any elevations i do not need. I then set the whole drawing to bylayer and change all layers to grey, then i check for any unresolved xrefs in the drawing and delete them. finally i purge the drawing before saving.