Finding a blocks insertion point and inserting a another block in the same spot.

[jpcadconsulting]

Hiya gang,

 

I've been messing around with this routine, trying to get it to place a point at the insertion poiutn of ALL selected blocks.

 

I've got this far, but it's only placing one point on one of the selected blocks...

 

(defun c:inspoint  (/ ss)
 (if (and (setq ss (ssget '((0 . "INSERT")))))
   (command "point"
            (cdr (assoc 10 (entget (ssname ss 0)))))
 )
 (princ))

 

Any help is as always, much appreciated.

[ronjonp]

You're only getting the first item in the selection set (ssname ss 0) ? You have to iterate the selection and place a point at each instance. IMO it would be better to use entmake for the point too.

 

Quick example:

(defun c:inspoint (/ ss)
 ;; RJP - 11.29.2017
 ;; Get selection
 (if (setq ss (ssget '((0 . "INSERT"))))
   ;; Convert to a list of enames (vl-remove-if 'listp .. then iterate list (foreach b ..
   (foreach b (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
     ;; Entmake a point on layer 'point' at insertion of block
     (entmakex (list '(0 . "point") '(8 . "point") (assoc 10 (entget b))))
   )
 )
 ;; Shhhhh
 (princ)
)

[jpcadconsulting]

Brilliant! I knew that was the issue, just not sure how to do anything about it. ;-)

 

Thanks!