FILLET lines continuous with crossing window ?

[gashaglava]

Is there a way to fillet lines continuous with crossing window ?

 

I tried the option "C" after running a FILLET, but it normally joins the 2 selected lines and then exits the command. if I ran it with Multiple option, I'd have to pick every pair of lines precisely, which could be very tedious.

 

Is there a way to make it continuous with crossing window? I would like to select another 2 lines with crossing window to fillet, and again, and again ... without having to enter the C option every time

 

I've seen that stuff in Powertools for AutoCAD, even with some advanced possibilities, but I'm not sure the pack is available for purchase anymore.

 

Thanks in advance !

Cheers

Edited March 13, 2012 by gashaglava
bad grammar :)

[eldon]

Whilst not being able to suggest an absolute solution to your wishes, have you tried making the Pickbox larger? Then you do not have to be so precise when picking the two lines.

[Tharwat]

Hope this help, and do not be surprised if lines went opposite way that you wanted

 

(defun c:test (/ ss sn1 sn2 e1 e2 p p1 p2) (vl-load-com)
;;; Tharwat 14. March . 2012 ;;;
 (defun Entmoding (key value ent)
   (entmod (subst (cons key value) (assoc key ent) ent))
 )
 (if
   (and (progn (princ "\n ***** Select only two lines to connect *****")
               (setq ss (ssget "_:L" '((0 . "LINE"))))
        )
        (eq (sslength ss) 2)
   )
    (progn
      (setq sn1 (ssname ss 0))
      (setq sn2 (ssname ss 1))
      (setq p (vlax-safearray->list
                (vlax-variant-value
                  (vla-intersectwith
                    (vlax-ename->vla-object sn1)
                    (vlax-ename->vla-object sn2)
                    acExtendBoth
                  )
                )
              )
      )
      (if (< (distance (cdr (assoc 10 (setq e1 (entget sn1)))) p)
             (distance (cdr (assoc 11 e1)) p)
          )
        (progn
          (setq p1 (cdr (assoc 11 e1)))
          (Entmoding 10 p e1)
        )
        (progn
          (setq p1 (cdr (assoc 10 e1)))
          (Entmoding 11 p e1)
        )
      )
      (if (< (distance (cdr (assoc 10 (setq e2 (entget sn2)))) p)
             (distance (cdr (assoc 11 e2)) p)
          )
        (progn
          (setq p2 (cdr (assoc 11 e2)))
          (Entmoding 10 p e2)
        )
        (progn
          (setq p2 (cdr (assoc 10 e2)))
          (Entmoding 11 p e2)
        )
      )
    )
    (princ)
 )
 (princ)
)

[alanjt]

I've had this macro in my startup for years...

 

;fillet (windowed) objects
(defun c:fc()(command "_.fillet" "_c")(princ))

Edited March 14, 2012 by alanjt

[pBe]

If you dont mind pressing escape afterwards you can use something like this

 

(defun c:fc  ()
     (command "fillet" "_multiple")
     (while (> (getvar "CMDACTIVE") 0)
           (command "c" pause pause)
           )
     )

[gashaglava]

eldon

thnx, but I would like to avoid that pickbox if possible

 

Tharwat

close enough ! ... I ran the "Multiple" command, than your "test", and it works very well. It would be great option if it filleted the lines immediately after selection (as fillet normally does, with crossing window), without having to press enter after selection ...

 

alanjt

seems to me this IS it, but I don't know how to run it ... I usually put some .lsp files in appload->contents, and they would load on startup ... and I'm not familiar with making macros ... help ?

 

pBe

does not work, or I'm doing something wrong ...

 

Thanks

Miroslav Gacesa

ACAD Architecture 2012

[pBe]

pbe

does not work.....

 

 

Ouch...

[Lee Mac]

seems to me this IS it, but I don't know how to run it ... I usually put some .lsp files in appload->contents, and they would load on startup ... and I'm not familiar with making macros ... help ?

 

Alan's code is still LISP, you can run it in the same way as you did with Tharwat's code, the command syntax is 'fc'.

[alanjt]

Alan's code is still LISP, you can run it in the same way as you did with Tharwat's code, the command syntax is 'fc'.

There you go.

[pBe]

gashaglava,

 

Just to be on the clear. What error mesage do you get when you run the snippet i posted?

It's doing what its supposed to do when i tried on another CAD station

[MSasu]

@pBe: Your routine works with current fillet radius and I suspect that OP had it set to 0; he/she need to call FILLET command first or use FILLETRAD system variable to set it.

 

Regards,

Mircea

[pBe]

@pBe: Your routine works with current fillet radius and I suspect that OP had it set to 0; he/she need to call FILLET command first or use FILLETRAD system variable to set it.

 

Regards,

Mircea

 

I would think there's more to it than that Mircea but thanks for the info ..... What else could be be causing the snippet to fail? .. anyone?

[gashaglava]

pBe,

 

here's the error message :

 

Command: fc

Unknown command "FILLET". Press F1 for help.

Enter command name to repeat: nil

[pBe]

Try it with "_.fillet"

[gashaglava]

Lee Mac,

 

here's the error message I get when I run alan's code :

 

Command: fc Unknown command "FILLET". Press F1 for help.

Unknown command "C". Press F1 for help.

[gashaglava]

pBe, that's it !

 

works great

 

Thanks !

[pBe]

@gashaglava

 

Cool beans.

Glad it worked for you.

 

@Mircea and @pBe

Language variation.... i should have known.

[alanjt]

Updated to account for language barriers. Sorry, I wrote that one looooong ago.

[Tharwat]

 

Tharwat

close enough ! ... I ran the "Multiple" command, than your "test", and it works very well. It would be great option if it filleted the lines immediately after selection (as fillet normally does, with crossing window), without having to press enter after selection ...

 

 

 

Try this one without pressing Enter

 

(defun c:test (/ a b ss sn1 sn2 e1 e2 p p1 p2)
 (vl-load-com)
;;; Tharwat 14. March . 2012 ;;;
 (defun Entmoding (key value ent)
   (entmod (subst (cons key value) (assoc key ent) ent))
 )
 (if
   (and (progn (princ "\n ***** Select only two lines to connect *****")
               (setq a (getpoint "\n First point:")
                     b (getcorner "\n Second point:" a)
               )
               (setq ss (ssget "_c" a b))
        )
        (eq (sslength ss) 2)
   )
    (progn
      (setq sn1 (ssname ss 0))
      (setq sn2 (ssname ss 1))
      (setq p (vlax-safearray->list
                (vlax-variant-value
                  (vla-intersectwith
                    (vlax-ename->vla-object sn1)
                    (vlax-ename->vla-object sn2)
                    acExtendBoth
                  )
                )
              )
      )
      (if (< (distance (cdr (assoc 10 (setq e1 (entget sn1)))) p)
             (distance (cdr (assoc 11 e1)) p)
          )
        (progn
          (setq p1 (cdr (assoc 11 e1)))
          (Entmoding 10 p e1)
        )
        (progn
          (setq p1 (cdr (assoc 10 e1)))
          (Entmoding 11 p e1)
        )
      )
      (if (< (distance (cdr (assoc 10 (setq e2 (entget sn2)))) p)
             (distance (cdr (assoc 11 e2)) p)
          )
        (progn
          (setq p2 (cdr (assoc 11 e2)))
          (Entmoding 10 p e2)
        )
        (progn
          (setq p2 (cdr (assoc 10 e2)))
          (Entmoding 11 p e2)
        )
      )
    )
    (princ)
 )
 (princ)
)

[gashaglava]

alanjt,

 

close enough ! ... if it only wouldnt exit the command after filleting first pair of lines

 

thanks anyway !