Change .lsp to .fas ?

[Mike55]

Can you give me a step by step instruction on changing .lsp to .fas first time.

If it help I have combined 32 programs in to one, and I have .dwg to pull in as the .lsp program is running.

[hoitdanger]

AutoCAD MEP 2012

 

Command line "Vlisp"

 

File > Make application > New application wizard.

 

Simple > Browse path for .fas to be saved at > Insert Name > Next

 

Add button > Find lisp routine(s) > Next > Check Build Application > Finish

 

Hope that helped!!

[Mike55]

Thanks for your time that is what I needed

[BIGAL]

Simple command line version (vlisp-compile 'st "c:\\temp\\test.lsp")

[mostafa badran]

I have good and easily lisp to do that.

;;  LSP2FAS.lsp                                    ; Scot Harris  11-29-2012
;;   Minimizes the sequence needed to create FAS files.
;;   Help facility added.
;;   Streamlined from original program provided by aqdam1978.

(defun c:LSP2FAS-Help (/)
(alert (strcat
 "\tLisp (LSP) to Fast and Secure (FAS) Help"
 "\n "
 "\nFile dialog begins in the current directory.   "
 "\nIt is suggested to place and open a drawing (DWG)   "
 "\ninside the input folder you wish to batch process.   "
 "\n "
 "\nOutput file will be in the same folder as the file selected.   "
 "\n "
 "\nThere is no provisional check for an existing FAS file of the same name.   "
))
);end LSP2FAS-Help

(defun c:LSP2FAS ( / a )
(vl-load-com)
(prompt " Lisp to Fast and Secure (FAS). LSP2FAS-Help available. ")
(if (wcmatch (strcase (setq a (getfiled "Convert LSP File to FAS" (getvar "DWGPREFIX") "" 16))) "*.LSP")
 (progn
  (c:vlide)(vlisp-compile 'st a)
  (princ (strcat "\n File " (vl-string-subst ".fas" ".lsp" a) " created. "))
 );progn
 (alert "File extension must be \".LSP\"   ")
);if
(princ)
);end LSP2FAS

[Snownut]

I use this and call acad from a batch file with the /b switch, so the files can be compiled without needing to be in ACAD first. Just double click to batch file on your desktop.

 

You can have compile from multiple directories and save in multiple directories with this method.

 

(defun Compile_NH ( )
 (vl-load-com)
 (c:vlide)
 (princ "\nPlease Wait Compiling in Process...\n")  
 (FOREACH x (vl-directory-files "C:\\Program Files\\Septic Assistant Program\\PC-LISP-AC-NH\\" "*.LSP" 1)
   (VLISP-COMPILE 'st (strcat "C:\\Program Files\\Septic Assistant Program\\PC-LISP-AC-NH\\" x)
                      (strcat "C:\\Program Files\\Septic Assistant\\New Hampshire\\FAS-AC\\" (vl-filename-base x) ".fas")
                      )
   )
 (FOREACH x (vl-directory-files "C:\\Program Files\\Septic Assistant Program\\PC-LISP-COMMON\\" "*.LSP" 1)
   (VLISP-COMPILE 'st (strcat "C:\\Program Files\\Septic Assistant Program\\PC-LISP-COMMON\\" x)
                      (strcat "C:\\Program Files\\Septic Assistant\\New Hampshire\\FAS-AC\\" (vl-filename-base x) ".fas")
                      )
   )  
 )