Find that drawing is Dynamic Block via dbx programming. how?

[Ahankhah]

Hi all,

is there a way to get informations from dbx opened drawing to find out that the drawing is indeed just a dynamic block?

 

It is for filtering those drawings stoped by alert box anouncing one of the following messages:

 

[Drawing name] contains authoring elements. open in Block Editor?

or

[Drawing name] contains authoring elements which cannot be edited. open drawing anyway?

 

I appreciate any help

[Lee Mac]

Try the following:

;; Dynamic Block File-p  -  Lee Mac
;; Returns T if the supplied drawing file is a dynamic block
;; dwg - [str] Drawing filename

(defun LM:dynamicblockfile-p ( dwg / doc lst rtn )
   (setq rtn
       (and (setq dwg (findfile dwg))
           (or
               (setq doc
                   (cdr
                       (assoc (strcase dwg)
                           (vlax-for doc (vla-get-documents (vlax-get-acad-object))
                               (setq lst (cons (cons (strcase (vla-get-fullname doc)) doc) lst))
                           )
                       )
                   )
               )
               (and
                   (setq doc
                       (vla-getinterfaceobject (vlax-get-acad-object)
                           (if (< (atoi (getvar 'acadver)) 16)
                               "objectdbx.axdbdocument"
                               (strcat "objectdbx.axdbdocument." (itoa (atoi (getvar 'acadver))))
                           )
                       )
                   )
                   (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-open (list doc dwg))))
               )
           )
           (= :vlax-true (vla-get-isdynamicblock (vla-get-modelspace doc)))
       )
   )
   (if (= 'vla-object (type doc))
       (vlax-release-object doc)
   )
   rtn
)

The above could (and should) be optimised if you intend to call the function from within a loop.

[Ahankhah]

Lee,

thank you very much for your prompt reply, as always.

I appreciate your great helps:D

[Lee Mac]

You're most welcome Ahankhah