LISP for Dimensioning from Multiple Points to Line

[comet712]

Hi, I'm looking for a routine where I can have auto dimension from multiple selected points to a line perpendicular to the points. Thank you in advance.

 

Dimension from Point to line.dwg

[BIGAL]

Here is a start for you, change the line to a dim command, next step is to pick all points and do in one go. Please have a go at modifying.

 

(setq oldsnap (getvar 'osmode))
(setq obj (vlax-ename->vla-object (car (entsel "\nPick line object"))))

(while
(setq pt (getpoint "pick point"))
(setq pt2 (vlax-curve-getClosestPointTo obj pt acextendnone))
(setvar 'osmode 0)
(command "line" pt pt2 "")
(setvar 'osmode oldsnap)
)

[comet712]

Hi BIGAL,

 

Thank you for your reply. However I have no background on LISP Programming.

I have tried my best to modify by changing the line to dim command as below. Still couldn't get it working though. Would you mind pointing out where went wrong?

(defun c:try2 ()



(setq oldsnap (getvar 'osmode))

(setq obj (vlax-ename->vla-object (car (entsel "\nPick line object"))))



(while

(setq pt (getpoint "pick point"))

(setq pt2 (vlax-curve-getClosestPointTo obj pt acextendnone))

(setvar 'osmode 0)

(command ".DIMLINEAR" pt pt2 "")

(setvar 'osmode oldsnap)

)

)

 

[BIGAL]

Very simple fix dim expects an offset point so

 

(command ".DIMLINEAR" pt pt2 pt )

[comet712]

Thanks BIGAL!

[Kumar1]

auto dimensioning by selecting multiple points and one line object

[devitg]

3 hours ago, Kumar1 said:

auto dimensioning by selecting multiple points and one line object

@Kumar1 please upload a sample.dwg with, at least, 2 o3 dim as you need it to be 

 

 

[Kumar1]

AutoDimensioning-VV.dwg

[Kumar1]

On 10/17/2017 at 3:00 PM, comet712 said:

Thanks BIGAL!

this lisp is fine, but instead of picking each point, can we write a lisp routine to select multiple points and write dimension automatically.

[Kumar1]

18 hours ago, devitg said:

@Kumar1 please upload a sample.dwg with, at least, 2 o3 dim as you need it to be 

 

 

this lisp is fine, but instead of picking each point, can we write a lisp routine to select multiple points and write dimension automatically. Sample File uploaded above.

[devitg]

5 hours ago, Kumar1 said:

this lisp is fine, but instead of picking each point, can we write a lisp routine to select multiple points and write dimension automatically. Sample File uploaded above.

@Kumar1 please make or send  a real dwg , with  points-layer, line-layer, dim-layer and a new dimstyle not an overrided style, so all variables system are stated . Like the first DWG posted  at this topic Dimension from Point to line.dwg

[pkenewell]

Here is a boiled down simple version with no error testing. It assumes that the dimensions will run on the same angle as the angle between the point and the curve segment:

;; Created by P. Kenewell 1/22/2026
(defun c:dim2pts (/ ep i p1 p2 p3 ss)
   (if
     (and
        (progn
           (princ "\nSelect Points to Dimension: ")
           (setq ss (ssget '((0 . "POINT"))))
        )
        (setq ep (entsel "\nSelect a curve to Dimension to: "))
     )
     (repeat (setq i (sslength ss))
        (setq p1 (cdr (assoc 10 (entget (ssname ss (setq i (1- i))))))
              p2 (vlax-curve-getclosestpointto (vlax-ename->vla-object (car ep)) p1)
              p3 (polar p1 (angle p1 p2) (/ (distance p1 p2) 2))
        )
        (command "._dimrotated" (* (/ (angle p1 p2) pi) 180.0) "_non" p1 "_non" p2 "_non" p3)
     )
   )
   (princ)
)

Example Screenshots:

 

 

 

 

 

Edited 26 minutes ago by pkenewell
Removed unnecessary (progn...)