Select objects by Color Lisp modification....

[Saqib_theleo]

Hello all there,

I have a Lisp "Select objects by color" which i downloaded from internet, exactly i don't remember from where.

(defun c:sbc ( / c d e l )
   (if (setq e (car (entsel)))
       (progn
           (setq c
               (cond
                   (   (cdr (assoc 62 (entget e)))   )
                   (   (abs (cdr (assoc 62 (tblsearch "LAYER" (cdr (assoc 8 (entget 

e)))))))   )
               )
           )                     
           (while (setq d (tblnext "LAYER" (null d)))
               (if (= c (abs (cdr (assoc 62 d))))
                   (setq l (cons "," (cons (cdr (assoc 2 d)) l)))
               )
           )
           (sssetfirst nil
               (ssget "_X"
                   (if l
                       (list
                           (cons -4 "<OR")
                               (cons 62 c)
                               (cons -4 "<AND")
                                   (cons 62 256)
                                   (cons 8 (apply 'strcat (cdr l)))
                               (cons -4 "AND>")
                           (cons -4 "OR>")
                       )
                       (list (cons 62 c))
                   )
               )
           )
       )
   )
   (princ)
)

This Lisp works fine for all objects of drawing. First it asks for select object (which color we want to select) then it selects all objects in the drawing of same color.

I want that after selecting color it asks for selection window instead of all drawing. If someone can help me modify this lisp I'll be thankful.

Thank you.

 

[JuniorNogueira]

Try removing "_X"

(ssget "_X"
	(if l
		...

 

[Saqib_theleo]

Hello JuniorNogueira,

thanks for your reply, i removed "_X" and it's now working as i wanted.

thanks for helping.

thank you..

[BIGAL]

For your future info look up help about SSGET its has a lot of filter options X W CP WP etc.

[BrianTFC]

this is a helpful lisp but what if you wanted to select by layer the same way?