subfix in dimension...

[leonucadomi]

hello all:

I need a routine that first asks me to enter "a word"

and this word is added to the value of the dimension below the line

example

 

The modified dimension shows this

 

 

Does anyone know of any code that can help me?

 

 

thanks

[Lee Mac]

Here's a quick one -

(defun c:dimsub ( / enx grp idx new pos sel str )
    (cond
        (   (= "" (setq str (getstring t "\nSpecify string: "))))
        (   (setq sel (ssget "_:L" '((0 . "*DIMENSION"))))
            (repeat (setq idx (sslength sel))
                (setq idx (1- idx)
                      enx (entget (ssname sel idx))
                      grp (assoc 1 enx)
                )
                (if (setq pos (vl-string-search "\\X" (cdr grp)))
                    (setq new (cons 1 (strcat (substr (cdr grp) 1 pos) "\\X" str)))
                    (setq new (cons 1 (strcat "<>\\X" str)))
                )
                (entmod (subst new grp enx))
            )
        )
    )
    (princ)
)

 

[leonucadomi]

7 minutes ago, Lee Mac said:

Here's a quick one -

(defun c:dimsub ( / enx grp idx new pos sel str )
    (cond
        (   (= "" (setq str (getstring t "\nSpecify string: "))))
        (   (setq sel (ssget "_:L" '((0 . "*DIMENSION"))))
            (repeat (setq idx (sslength sel))
                (setq idx (1- idx)
                      enx (entget (ssname sel idx))
                      grp (assoc 1 enx)
                )
                (if (setq pos (vl-string-search "\\X" (cdr grp)))
                    (setq new (cons 1 (strcat (substr (cdr grp) 1 pos) "\\X" str)))
                    (setq new (cons 1 (strcat "<>\\X" str)))
                )
                (entmod (subst new grp enx))
            )
        )
    )
    (princ)
)

 

i will try master thanks

[leonucadomi]

EXCELLENT...

You can make it so that by default it suggests the word "typ" so that with just one enter I can continue the routine and if in the future I need to add another word I can change it.

[Lee Mac]

36 minutes ago, leonucadomi said:

You can make it so that by default it suggests the word "typ" so that with just one enter I can continue the routine and if in the future I need to add another word I can change it.

For a "fixed" default, you can use something like the following:

(defun c:dimsub ( / enx grp idx new pos sel str )
    (if (= "" (setq str (getstring t "\nSpecify string <TYP>: ")))
        (setq str "TYP")
    )
    (if (setq sel (ssget "_:L" '((0 . "*DIMENSION"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  grp (assoc 1 enx)
            )
            (if (setq pos (vl-string-search "\\X" (cdr grp)))
                (setq new (cons 1 (strcat (substr (cdr grp) 1 pos) "\\X" str)))
                (setq new (cons 1 (strcat "<>\\X" str)))
            )
            (entmod (subst new grp enx))
        )
    )
    (princ)
)

For a "dynamic" default, you can use one of the methods I describe here.

[BIGAL]

Interesting ""Windows Speech Recognition," and then use the shortcut Windows logo key + Ctrl + S to activate it.

 

Typed dimsub then spoke T Y P a box appeared then did accept. !typ = "TYP " very close.

 

It did 1st go put EYP  in command line. So I think I need to train it more. Can turn on and off microphone by voice. 

 

If I have time may play more.

 

[leonucadomi]

On 3/7/2025 at 5:58 PM, Lee Mac said:

For a "fixed" default, you can use something like the following:

(defun c:dimsub ( / enx grp idx new pos sel str )
    (if (= "" (setq str (getstring t "\nSpecify string <TYP>: ")))
        (setq str "TYP")
    )
    (if (setq sel (ssget "_:L" '((0 . "*DIMENSION"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  grp (assoc 1 enx)
            )
            (if (setq pos (vl-string-search "\\X" (cdr grp)))
                (setq new (cons 1 (strcat (substr (cdr grp) 1 pos) "\\X" str)))
                (setq new (cons 1 (strcat "<>\\X" str)))
            )
            (entmod (subst new grp enx))
        )
    )
    (princ)
)

For a "dynamic" default, you can use one of the methods I describe here.

master , I am trying to do the following

 

(defun c:dimsub ( / enx grp idx new pos sel str )
(princ "\nColoca subfijo a dimension por debajo de linea con opcion de cambio")
   ; (if (= "" (setq str (getstring t "\nSpecify string <TYP>: ")))
        ;(setq str "TYP")
   ; )
    (if (setq sel (ssget "_:L" '((0 . "*DIMENSION"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  grp (assoc 1 enx)
            )
            (if (setq pos (vl-string-search "\\X" (cdr grp)))
                (setq new (cons 1 (strcat (substr (cdr grp) 1 pos) "\\X" str)))
                (setq new (cons 1 (strcat "+" "<>\\X" "TEXT 1")))
                
            )
            (entmod (subst new grp enx))
        )
    )
    (princ)
)

[leonucadomi]

I NEED TO ADD A SECOND TEXT BELOW THE FIRST

[GLAVCVS]

Another option

(defun c:subTexta (/ e le txa tx cj para)
  (if (/= (setq tx (getstring "\nType TEXT to add?: ")) "")
    (while (setq n (not (setvar "NOMUTT" 1)) x (princ (strcat "\rAdd \'" tx "\' to DIMENSIONs...")) cj (ssget "_:L" '((0 . "*DIMENSION"))))
      (while (setq e (ssname cj (setq n (if n (1+ n) 0))))
	(entmod (subst
		  (cons 1 (cond ((or (wcmatch (setq txa (cdr (assoc 1 (setq le (entget e))))) "*<>\n*") (wcmatch txa "*<>\\X*")) (strcat txa "\n" tx)) (T (strcat txa "<>\\X" tx))))
		  (assoc 1 le)
		  le
		)
	)
      )
    )
  )
  (setvar "NOMUTT" 0) 
  (princ)
)

 

Edited 12 minutes ago by GLAVCVS

[GLAVCVS]

2 minutes ago, GLAVCVS said:

Another option

(defun c:subTexta (/ e le txa tx cj para)
  (if (/= (setq tx (getstring "\nType TEXT to add?: ")) "")
    (while (setq n (not (setvar "NOMUTT" 1)) x (princ (strcat "\rAdd \'" tx "\' to DIMENSIONs...")) cj (ssget "_:L" '((0 . "*DIMENSION"))))
      (while (setq e (ssname cj (setq n (if n (1+ n) (setvar "NOMUTT" 0)))))
	(entmod (subst
		  (cons 1 (cond ((or (wcmatch (setq txa (cdr (assoc 1 (setq le (entget e))))) "*<>\n*") (wcmatch txa "*<>\\X*")) (strcat txa "\n" tx)) (T (strcat txa "<>\\X" tx))))
		  (assoc 1 le)
		  le
		)
	)
      )
    )
  )
  (princ)
)

 

 

To add all the text lines you need

Edited 32 minutes ago by GLAVCVS

[GLAVCVS]

@leonucadomi

You should copy the code again.

I changed a small thing to prevent NOMUTT from staying at 1.