Break Polyline at different depth

[Mohamed Haytham]

Hi, It would be great if you can help me with the following.

I have multiple polylines where they have different widths (Originally creating by fillet a line with width 1 and a line with width 2).

Is there a way to split them to the original state where the are 2 lines and each has it's actual widths?

 

I am attaching a file with the issue, and the expected solution, but this is only file with 2 polylines as an example, but this issue is happening with a file having more than 1000 polyline.

Break Polyline at different depth.dwg

[Nikon]

Try this code

;; author ::Jaifl::
;; divides polylines into separate segments, preserving thickness, color, layer
(defun c:SplitPlSeg ( / ss i ent elist points widths bulges n j p1 p2 w1 w2 bulge color layer ltype lweight transp)
  (setq ss (ssget '((0 . "LWPOLYLINE"))))
  (if ss
    (progn
      (setq i 0)
      (while (< i (sslength ss))
        (setq ent (ssname ss i))
        (setq elist (entget ent))
        
        (setq color (assoc 62 elist))      
        (setq layer (assoc 8 elist))       
        (setq ltype (assoc 6 elist))       
        (setq lweight (assoc 370 elist))   
        (setq transp (assoc 440 elist))    
        
        (setq points '() widths '() bulges '())
        (foreach x elist
          (cond
            ((= (car x) 10) (setq points (append points (list (cdr x)))))
            ((= (car x) 40) (setq widths (append widths (list (cdr x)))))
            ((= (car x) 41) (setq widths (append widths (list (cdr x)))))
            ((= (car x) 42) (setq bulges (append bulges (list (cdr x)))))
          )
        )
        (setq n (length points))
        (setq j 0)
        (while (< j (1- n))
          (setq p1 (nth j points))
          (setq p2 (nth (+ j 1) points))
          (setq w1 (nth (* j 2) widths))   ; Start width
          (setq w2 (nth (1+ (* j 2)) widths)) ; End width
          (setq bulge (if (< j (length bulges)) (nth j bulges) 0.0))
         
          (setq newent
            (append
              (list
                (cons 0 "LWPOLYLINE")
                (cons 100 "AcDbEntity")
                layer
              )
              (if color (list color) '())
              (if ltype (list ltype) '())
              (if lweight (list lweight) '())
              (if transp (list transp) '())
              (list
                (cons 100 "AcDbPolyline")
                (cons 90 2)
                (cons 70 0)
                (list 10 (car p1) (cadr p1))
                (cons 40 w1)
                (cons 41 w2)
                (cons 42 bulge)
                (list 10 (car p2) (cadr p2))
                (cons 40 w2)
                (cons 41 w2)
              )
            )
          )
          (entmake newent)
          (setq j (1+ j))
        )
        (entdel ent) ; delete the original polyline
        (setq i (1+ i))
      )
    )
    (princ "There are no selected polylines.")
  )
  (princ)
)

 

[ronjonp]

Another for fun:
 

(defun c:foo (/ a b el l s w)
  ;; RJP » 2025-07-23
  ;; Creates separate polyline segments preserving widths etc..
  (cond	((setq s (ssget '((0 . "LWPOLYLINE"))))
	 (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
	   (setq el (entget e))
	   (setq a (append (reverse (member '(100 . "AcDbPolyline") (reverse el))) '((90 . 2))))
	   (setq b (vl-remove-if-not '(lambda (x) (member (car x) '(10 40 41 42))) el))
	   (while (cddddr b)
	     (setq l (list (car b) (cadr b) (caddr b) (cadddr b)))
	     (setq w ;; Set global width if start and end are 'equal'
		     (if (equal (cdadr b) (cdaddr b) 1e-4)
		       (list (cons 43 (cdadr b)))
		     )
	     )
	     (setq b (cddddr b))
	     (entmakex (append a (append l w (list (car b) (cadr b) (caddr b) (cadddr b)))))
	   )
	   (entdel e)
	 )
	)
  )
  (princ)
)

 

Edited 2 hours ago by ronjonp

[marko_ribar]

I might be wrong, but can this be achieved just by using EXPLODE command?

 

[EDIT : I see it now... EXPLODE command converts segments into LINE and ARC entities, so widths are lost...]

Edited yesterday at 06:24 AM by marko_ribar

[Emmanuel Delay]

13 minutes ago, marko_ribar said:

I might be wrong, but can this be achieved just by using EXPLODE command?

 

Exploding polylines makes lines.  Lines have no width.

The question is to "explode", but keep all edges as polyline with the original width

[Tsuky]

Yet another...

(defun c:break_lw ( / js i ent dxf_obj dxf_43 dxf_38 dxf_39 dxf_10 dxf_40 dxf_41 dxf_42 dxf_39 dxf_210 n)
  (initget "All Select")
  (if (eq (getkword "\nLWPolylines to break at each vertex? [All/Select] <Select>: ") "All")
    (setq
      js
        (ssget "_X" 
          (list
            (cons 0 "LWPOLYLINE")
            (cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
            (cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
          )
        )
      i -1
    )
    (setq
      js
        (ssget
          (list
            (cons 0 "LWPOLYLINE")
            (cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
            (cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
          )
        )
      i -1
    )
  )
  (cond
    (js
      (repeat (sslength js)
        (setq dxf_obj (entget (setq ent (ssname js (setq i (1+ i))))))
        (if (cdr (assoc 43 dxf_obj))
          (setq dxf_43 (cdr (assoc 43 dxf_obj)))
          (setq dxf_43 0.0)
        )
        (if (cdr (assoc 38 dxf_obj))
          (setq dxf_38 (cdr (assoc 38 dxf_obj)))
          (setq dxf_38 0.0)
        )
        (if (cdr (assoc 39 dxf_obj))
          (setq dxf_39 (cdr (assoc 39 dxf_obj)))
          (setq dxf_39 0.0)
        )
        (setq
          dxf_10 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) dxf_obj))
          dxf_40 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 40)) dxf_obj))
          dxf_41 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 41)) dxf_obj))
          dxf_42 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 42)) dxf_obj))
          dxf_210 (cdr (assoc 210 dxf_obj))
        )
        (if (not (zerop (boole 1 (cdr (assoc 70 dxf_obj)) 1)))
          (setq
            dxf_10 (append dxf_10 (list (car dxf_10)))
            dxf_40 (append dxf_40 (list (car dxf_40)))
            dxf_41 (append dxf_41 (list (car dxf_41)))
            dxf_42 (append dxf_42 (list (car dxf_42)))
            n (cdr (assoc 90 dxf_obj))
          )
          (setq n (1- (cdr (assoc 90 dxf_obj))))
        )
        (repeat n
          (entmake
            (list
              (cons 0 "LWPOLYLINE")
              (cons 100 "AcDbEntity")
              (assoc 67 dxf_obj)
              (assoc 410 dxf_obj)
              (assoc 8 dxf_obj)
              (if (assoc 62 dxf_obj) (assoc 62 dxf_obj) (cons 62 256))
              (if (assoc 6 dxf_obj) (assoc 6 dxf_obj) (cons 6 "BYLAYER"))
              (if (assoc 370 dxf_obj) (assoc 370 dxf_obj) (cons 370 -1))
              (cons 100 "AcDbPolyline")
              (cons 90 2)
              (cons 70 (boole 1 (cdr (assoc 70 dxf_obj)) 128))
              (cons 38 dxf_38)
              (cons 39 dxf_39)
              (cons 10 (car dxf_10))
              (cons 40 (car dxf_40))
              (cons 41 (car dxf_41))
              (cons 42 (car dxf_42))
              (cons 10 (cadr dxf_10))
              (cons 40 (cadr dxf_40))
              (cons 41 (cadr dxf_41))
              (cons 42 (cadr dxf_42))
              (assoc 210 dxf_obj)
            )
          )
          (setq dxf_10 (cdr dxf_10) dxf_40 (cdr dxf_40) dxf_41 (cdr dxf_41) dxf_42 (cdr dxf_42))
        )
        (entdel ent)
      )
      (print (sslength js)) (princ " LWpolyline(s) breaked at its vertexs.")
    )
  )
  (prin1)
)

 

[Mohamed Haytham]

Thanks all for providing different lisps. All worked perfect in terms of breaking the poly, but I have one small issue, the global width is remained undefined. Is there a way even with a different lisp to assign the Global width from the start / End segment width?

 

[Nikon]

4 hours ago, Mohamed Haytham said:

the global width is remained undefined.

If a polyline consists of several segments and they have different widths, then the global width is not defined in the properties.

If a polyline from the same segment has different starting and ending widths, then the global width is also not defined in the properties.

The global width in the properties is displayed only for a polyline of several segments of the same width or a polyline of the same segment with the same starting and ending widths.

If you want to set the same global width of the polylines, simply select all the polylines and set the desired width in the properties.
Or did I misunderstand what you want to do?..

Edited 6 hours ago by Nikon

[Tsuky]

Try the code modified.

If equal starting and ending widths or global width is define, the global width is individual set otherwise is ignored.

Also takes into account the last segment if the polyline is closed as well as the generation of the linetype as well as the UCS of the original entity

(defun c:break_lw ( / js i ent dxf_obj dxf_43 dxf_38 dxf_39 dxf_10 dxf_40 dxf_41 dxf_42 dxf_39 dxf_210 n)
  (initget "All Select")
  (if (eq (getkword "\nLWPolylines to break at each vertex? [All/Select] <Select>: ") "All")
    (setq
      js
        (ssget "_X" 
          (list
            (cons 0 "LWPOLYLINE")
            (cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
            (cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
          )
        )
      i -1
    )
    (setq
      js
        (ssget
          (list
            (cons 0 "LWPOLYLINE")
            (cons 67 (if (eq (getvar "CVPORT") 2) 0 1))
            (cons 410 (if (eq (getvar "CVPORT") 2) "Model" (getvar "CTAB")))
          )
        )
      i -1
    )
  )
  (cond
    (js
      (repeat (sslength js)
        (setq dxf_obj (entget (setq ent (ssname js (setq i (1+ i))))))
        (if (cdr (assoc 43 dxf_obj))
          (setq dxf_43 (cdr (assoc 43 dxf_obj)))
          (setq dxf_43 nil)
        )
        (if (cdr (assoc 38 dxf_obj))
          (setq dxf_38 (cdr (assoc 38 dxf_obj)))
          (setq dxf_38 0.0)
        )
        (if (cdr (assoc 39 dxf_obj))
          (setq dxf_39 (cdr (assoc 39 dxf_obj)))
          (setq dxf_39 0.0)
        )
        (setq
          dxf_10 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) dxf_obj))
          dxf_40 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 40)) dxf_obj))
          dxf_41 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 41)) dxf_obj))
          dxf_42 (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 42)) dxf_obj))
          dxf_210 (cdr (assoc 210 dxf_obj))
        )
        (if (not (zerop (boole 1 (cdr (assoc 70 dxf_obj)) 1)))
          (setq
            dxf_10 (append dxf_10 (list (car dxf_10)))
            dxf_40 (append dxf_40 (list (car dxf_40)))
            dxf_41 (append dxf_41 (list (car dxf_41)))
            dxf_42 (append dxf_42 (list (car dxf_42)))
            n (cdr (assoc 90 dxf_obj))
          )
          (setq n (1- (cdr (assoc 90 dxf_obj))))
        )
        (repeat n
          (entmake
            (append
              (list
                (cons 0 "LWPOLYLINE")
                (cons 100 "AcDbEntity")
                (assoc 67 dxf_obj)
                (assoc 410 dxf_obj)
                (assoc 8 dxf_obj)
                (if (assoc 62 dxf_obj) (assoc 62 dxf_obj) (cons 62 256))
                (if (assoc 6 dxf_obj) (assoc 6 dxf_obj) (cons 6 "BYLAYER"))
                (if (assoc 370 dxf_obj) (assoc 370 dxf_obj) (cons 370 -1))
                (cons 100 "AcDbPolyline")
                (cons 90 2)
                (cons 70 (boole 1 (cdr (assoc 70 dxf_obj)) 128))
                (cons 38 dxf_38)
                (cons 39 dxf_39)
                (cons 10 (car dxf_10))
              )
              (cond
                (dxf_43
                  (list
                    (cons 43 dxf_43)
                    (cons 40 dxf_43)
                    (cons 41 dxf_43)
                  )
                )
                ((equal (car dxf_40) (car dxf_41))
                  (list
                    (cons 43 (car dxf_40))
                    (cons 40 (car dxf_40))
                    (cons 41 (car dxf_41))
                  )
                )
                (T
                  (list
                    (cons 40 (car dxf_40))
                    (cons 41 (car dxf_41))
                  )
                )
              )
              (list
                (cons 42 (car dxf_42))
                (cons 10 (cadr dxf_10))
              )
              (cond
                (dxf_43
                  (list
                    (cons 43 dxf_43)
                    (cons 40 dxf_43)
                    (cons 41 dxf_43)
                  )
                )
                ((equal (car dxf_40) (car dxf_41))
                  (list
                    (cons 43 (car dxf_40))
                    (cons 40 (car dxf_40))
                    (cons 41 (car dxf_41))
                  )
                )
                (T
                  (list
                    (cons 40 (car dxf_40))
                    (cons 41 (car dxf_41))
                  )
                )
              )
              (list
                (cons 42 (cadr dxf_42))
                (assoc 210 dxf_obj)
              )
            )
          )
          (setq dxf_10 (cdr dxf_10) dxf_40 (cdr dxf_40) dxf_41 (cdr dxf_41) dxf_42 (cdr dxf_42))
        )
        (entdel ent)
      )
      (print (sslength js)) (princ " LWpolyline(s) breaked at its vertexs.")
    )
  )
  (prin1)
)

 

[ronjonp]

@Mohamed Haytham

 

Code updated to preserve global width.

 

Edited 2 hours ago by ronjonp