UnFormat.lsp does not work in Autocad 2021

August 13

This code does not work in Autocad 2021 (localized version), the selected MText is being deleted.
How can this be fixed?

; UnFormat MText, MLeader, Table - strip formatting contol codes from texts
;
; based on Lee Mac's UnFormat string - www.lee-mac.com/unformatstring.html
; CAD Studio, 2018, www.cadstudio.cz  www.cadforum.cz
;
;
(vl-load-com)

;;-------------------=={ UnFormat String }==------------------;;
;;                                                            ;;
;;  Returns a string with all MText formatting codes removed. ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  str - String to Process                                   ;;
;;  mtx - MText Flag (T if string is for use in MText)        ;;
;;------------------------------------------------------------;;
;;  Returns:  String with formatting codes removed            ;;
;;------------------------------------------------------------;;

(defun LM:UnFormat ( str mtx / _replace rx )

    (defun _replace ( new old str )
        (vlax-put-property rx 'pattern old)
        (vlax-invoke rx 'replace str new)
    )
    (if (setq rx (vlax-get-or-create-object "VBScript.RegExp"))
        (progn
            (setq str
                (vl-catch-all-apply
                    (function
                        (lambda ( )
                            (vlax-put-property rx 'global     actrue)
                            (vlax-put-property rx 'multiline  actrue)
                            (vlax-put-property rx 'ignorecase acfalse) 
                            (foreach pair
                               '(
                                    ("\032"    . "\\\\\\\\")
                                    (" "       . "\\\\P|\\n|\\t")
                                    ("$1"      . "\\\\(\\\\[ACcFfHLlOopQTW])|\\\\[ACcFfHLlOopQTW][^\\\\;]*;|\\\\[ACcFfHLlOopQTW]")
                                    ("$1$2/$3" . "([^\\\\])\\\\S([^;]*)[/#\\^]([^;]*);")
                                    ("$1$2"    . "\\\\(\\\\S)|[\\\\](})|}")
                                    ("$1"      . "[\\\\]({)|{")
                                )
                                (setq str (_replace (car pair) (cdr pair) str))
                            )
                            (if mtx
                                (_replace "\\\\" "\032" (_replace "\\$1$2$3" "(\\\\[ACcFfHLlOoPpQSTW])|({)|(})" str))
                                (_replace "\\"   "\032" str)
                            )
                        )
                    )
                )
            )
            (vlax-release-object rx)
            (if (null (vl-catch-all-error-p str))
                str
            )
        )
    )
)
;-----------------

(defun doUnformatTable (table / rowCounter colCounter)
 (setq rowCounter (vla-Get-Rows table))
 (repeat rowCounter
 (setq rowCounter (1- rowCounter))
 (setq colCounter (vla-Get-Columns table))
 (repeat colCounter
  (setq colCounter (1- colCounter))
  (setq cellType (vla-GetCellType table rowCounter colCounter))
  (if (= cellType acTextCell)(progn
         (setq cellText (vla-GetText table rowCounter colCounter))
         (if (/= cellText "")
          (vla-SetText table rowCounter colCounter (LM:UnFormat cellText T)))
  ))
 ) ; rep
 ) ; rep
)

(defun c:UNFORMAT (/ ss ssl cnt en xxobj otyp txr ntx)
 (princ "\nSelect MTEXTs/DIMENSIONs/MLEADERs/TABLEs: ")
 (setq ss (ssget '((0 . "MTEXT,DIMENSION,MULTILEADER,ACAD_TABLE"))))
 (if (and ss (> (setq ssl (sslength ss)) 0))(progn
  (setq cnt 0)
  (repeat ssl
    (setq en (ssname ss cnt))
	(setq obj (vlax-ename->vla-object en))
	(setq otyp (cdr (assoc 0 (entget en)))) ; (vla-get-objectname obj))
	(cond
	 ((= otyp "MTEXT")(vla-put-TextString obj (LM:UnFormat (vla-get-TextString obj) T))) ; AcDbMText
	 ((= otyp "DIMENSION")(vla-put-TextOverride obj (LM:UnFormat (vla-get-TextOverride obj) T))) ; AcDbRotatedDimension, AcDbAlignedDimension
	 ((= otyp "MULTILEADER")(vla-put-TextString obj(LM:UnFormat (vla-get-TextString obj) T))) ; AcDbMLeader
	 ((= otyp "ACAD_TABLE")(doUnformatTable obj)) ; AcDbTable
	)
	(setq cnt (1+ cnt))
  ) ;rep
 )
 (princ "\nNothing selected!")
 ) ;if
 (princ)
)

(princ "\nUNFORMAT loaded.")
(princ)

August 13

You should post a sample drawing.

August 14

9 hours ago, ronjonp said:

You should post a sample drawing.

In Autocad 2015, the code worked correctly, in Autocad 2021,
texts containing control codes are deleted after selection...

Unformat not work in Autocad 2021.dwg

Edited August 14 by Nikon

August 14

It was working OK for me in your sample drawing - I am using 2022 though but would expect any changes in 2021 to be carried through to that.

Looking at the LISP, there is nothing in there to delete any texts, try loading it last in case there is another LISP loaded with the same name as some of the sub routines and try again maybe

Edited August 14 by Steven P

August 14

Works in AutoCAD 2026.

Try restarting AutoCAD, then a reset to defaults if that doesn't work.

August 14

If you haven't solved it yet, there's another possibility:
Replace '(setq en (ssname ss cnt))' with '(setq en (ssname ss cnt)) ex en)'
Load the code and run it again.
Then, type '(entget ex)' on the command line.
If it returns the entity list, see if '(60 . 1)' appears anywhere.

August 14

2 hours ago, GLAVCVS said:

If you haven't solved it yet, there's another possibility:
Replace '(setq en (ssname ss cnt))' with '(setq en (ssname ss cnt)) ex en)'
Load the code and run it again.
Then, type '(entget ex)' on the command line.
If it returns the entity list, see if '(60 . 1)'.

texts containing control codes are deleted after selection...

Reaction to the Command: (entget ex)
; error: invalid argument type: lentityp nil

August 16

I agree with StevenP.

I've tested Lee Mac's code in the 2021 version, and it works fine in your drawing.

It's probably some interference between your loaded Lisp code.

August 16

55 minutes ago, GLAVCVS said:

I agree with StevenP.

I've tested Lee Mac's code in the 2021 version, and it works fine in your drawing.

It's probably some interference between your loaded Lisp code.

Is there a way to find this intervention?

I have two more codes with this function that don't work...

Edited August 16 by Nikon

August 16

Try this as an experiment:

(Defun C:LMUnF ( / )
  (Load " -NIKON LISP FILEPATH- \\LM-Unformat.lsp") (c:UNFORMAT)(princ)
)

Where -Nikon Lisp Filepath is where the file is saved, LM-Unformat.lsp is the file name.

It should load this file when you run 'LMUnf' - and since it is the latest loaded will take precedence over anything loaded previously,

Second option is to modify the text using entmod perhaps

Edited August 16 by Steven P

August 16

On 8/16/2025 at 12:42 PM, Steven P said:

It should load this file when you run 'LMUnf' - and since it is the latest loaded will take precedence over anything loaded previously,

Thank you all for your advice.
I've tried all the options. It doesn't work…

There is no file UNFORMAT in the startup, I open a new file, download lisp UNFORMAT and nothing changes...

Mysticism?!?

Edited August 18 by Nikon

August 16

36 minutes ago, Nikon said:

There is no file UNFORMAT in the startup,

You'll need to apply some thought there, use the filename and location of where you have saved the LSP file containing the unformat lisps you posted above.

August 16

4 hours ago, Nikon said:

Is there a way to find this intervention?

Yes

This, for Eixample

;*******************  p o r d e s í a r g o  ********************
;************************ G L A V C V S *************************
;************************** F E C I T ***************************
(defun c:buscaDefunsRepets (/ lstLsps arch  nmarch linea lst as nbref separa<->palabras lstDefuns lstRepets tit dale path escrutArch)
  
  (defun separa<->palabras (tx lstCtrs / c p l)
    (foreach c (vl-string->list tx)
      (if (member (setq c (chr c)) lstCtrs)
        (if p (setq l (cons p l) p nil))
        (setq p (if p (strcat p c) c))
      )
    )
    (reverse (if p (cons p l) l))
  )

  (defun escrutArch (nmarch / arch linea lst as nbref)
    (if (and (setq nmarch (findfile nmarch)) (setq arch (open nmarch "r")))
      (while (setq linea (read-line arch))
	(cond
	  ((wcmatch linea "*(defun *")
	      (setq lst (separa<->palabras linea ;'(" " "("))
		    '(" " "(" "\""))
		    as (assoc (setq nbref (cadr lst)) lstDefuns)
	      )
	      (if lstDefuns
	        (if (not (vl-some ; comprobamos cada defun acumulada
			   '(lambda (v)
			      (if (and (= (car v) nbref) (/= nbref "defun")); si la defun recien leída coincide con alguna de las encontradas anteriormente
			        (if (setq lr (assoc nbref lstRepets))
				  (setq lstRepets (subst (append lr (list nmarch)) lr lstRepets))
				  (setq lstRepets (append lstRepets (list (append v (list nmarch)))))
			        )
		  	      )
			    )
			   lstDefuns
	       	         )
		    )
		  (setq lstDefuns (append lstDefuns (list (list nbref nmarch))))
	        )
	        (setq lstDefuns (append lstDefuns (list (list nbref nmarch))))
	      )
	    )
	)
      )
    )
    (if arch (close arch))
  )
  
  (setq lstLsps (list "acad2021.lsp" "acad2021doc.lsp") extens '("lsp"))
  (foreach lsp lstLsps
    (if (and (findfile lsp) (setq arch (open (setq nmarch (findfile lsp)) "r")))
      (progn
	(while (setq linea (read-line arch))
	  (cond
	    ((wcmatch linea "*(defun *")
	      (setq lst (separa<->palabras linea '(" " "("))
		    as (assoc (setq nbref (cadr lst)) lstDefuns)
	      )
	      (if lstDefuns
	        (if (not (vl-some ; comprobamos cada defun acumulada
			   '(lambda (v)
			      (if (and (= (car v) nbref) (/= nbref "defun")); si la defun recien leída coincide con alguna de las encontradas anteriormente
			        (if (setq lr (assoc nbref lstRepets))
				  (setq lstRepets (subst (append lr (list nmarch)) lr lstRepets))
				  (setq lstRepets (append lstRepets (list (append v (list nmarch)))))
			        )
		  	      )
			    )
			   lstDefuns
	       	         )
		    )
		  (setq lstDefuns (append lstDefuns (list (list nbref nmarch))))
	        )
	        (setq lstDefuns (append lstDefuns (list (list nbref nmarch))))
	      )
	    )
	    ((wcmatch linea "*(load *\")*")
	     (setq lst (separa<->palabras linea '(" " "(" "\""));'(" " "("))
		   as (assoc (setq nbref (cadr lst)) lstDefuns)
	     )
	     (foreach v lst
	       (if dale
		 (setq dale
			(if (and
			      (not (member (strcase v T) (list "acad2021.lsp" "acad2021doc.lsp")))
			      (or 
			        (= (length (setq lst1 (separa<->palabras v '(".")))) 1)
				(member (strcase (cadr lst1) T) extens)
			      )
			    )
			  (escrutArch v)
			)
		       dale nil
		 )
	         (if (= (strcase v T) "load")
		   (setq dale T)
		 )
	       )
	       (if nmArch1 (escrutArch nmArch1))
	     )
	    )
	  )
	)
      )
    )
  )
	    
  (if arch (close arch))
		      
  (if lstRepets
    (if (setq arch (open (setq nmarch (strcat (VL-REGISTRY-READ "HKEY_CURRENT_USER\\Software\\Microsoft\\Windows\\CurrentVersion\\Explorer\\Shell Folders" "Personal") "\\informe.txt")) "w"))
      (foreach lr lstRepets
	(princ (strcat (if (not tit) (setq tit "FUNCTIONS DEFINED MULTIPLE TIMES:\n") "") "\n    Function NAME \'" (car lr) "\' in:\n") arch)
	(foreach path (cdr lr)
	  (princ (strcat "\t" path "\n") arch)
	)
      )
    )
  )
  (if arch (progn (close arch) (startapp "notepad" nmarch)))
  (princ)
)

Try it

August 16

PS:

The command will analyze the code in the files in the 'lstLsps' list and any files loaded from them. However, it will not analyze any files loaded from the latter. That is, it will not analyze code loaded beyond the second level of nesting.

But I think that should be enough.

Edited August 16 by GLAVCVS

August 16

@GLAVCVS thank you very much!

I run the command buscaDefunsRepets and I get this message:

FUNCTIONS DEFINED MULTIPLE TIMES:

Function NAME '*merr*' in:
C:\Users\Nikon\AppData\Roaming\Autodesk\AutoCAD 2021\R24.0\rus\support\acad2021doc.lsp
C:\Users\Nikon\AppData\Roaming\Autodesk\AutoCAD 2021\R24.0\rus\support\acad2021doc.lsp

Function NAME '*merrmsg*' in:
C:\Users\Nikon\AppData\Roaming\Autodesk\AutoCAD 2021\R24.0\rus\support\acad2021doc.lsp
C:\Users\artem\Nikon\AppData\Roaming\Autodesk\AutoCAD 2021\R24.0\rus\support\acad2021doc.lsp

What do I need to do next?

acad2021doc.lsp

...........

(defun *merr* (msg)
(setq *error* m:err m:err nil)
(princ)
)

(defun *merrmsg* (msg)
(princ msg)
(setq *error* m:err m:err nil)
(princ)
)

...................

Edited August 16 by Nikon

August 16

1 hour ago, Nikon said:

@GLAVCVS

(defun *merr* (msg)
(setq *error* m:err m:err nil)
(princ)
)

(defun *merrmsg* (msg)
(princ msg)
(setq *error* m:err m:err nil)
(princ)
)

...................

Those functions have nothing to do with your problem.

Your code doesn't work in any drawing?

Edited August 16 by GLAVCVS

August 16

42 minutes ago, GLAVCVS said:

Your code doesn't work in any drawing?

Yes!

I checked the code in Autocad 2019, it works great!

Edited August 16 by Nikon

August 16

I've modified the code so that it also analyzes the files loaded from the profile.

;*******************  p o r d e s í a r g o  ********************
;************************ G L A V C V S *************************
;************************** F E C I T ***************************
(defun c:buscaDefunsRepets (/ lstLsps arch  nmarch linea lst as nbref separa<->palabras lstDefuns lstRepets tit i dale path escrutArch)
  
  (defun separa<->palabras (tx lstCtrs / c p l)
    (foreach c (vl-string->list tx)
      (if (member (setq c (chr c)) lstCtrs)
        (if p (setq l (cons (strcase p T) l) p nil))
        (setq p (if p (strcat p c) c))
      )
    )
    (reverse (if p (cons (strcase p T) l) l))
  )

  (defun escrutArch (nmarch / arch linea lst as nbref dale mirExtens)
    (defun mirExtens (nmarch)
      (if (not (wcmatch nmarch "*[.]@@@"))
	(strcat nmarch ".lsp")
	nmarch
      )
    )
    (if (and (setq nmarch (findfile (mirExtens nmarch))) (setq arch (open nmarch "r")))
      (while (setq linea (read-line arch))
	(cond
	  ((and (wcmatch linea "*(defun *") (not (wcmatch linea "*\"(defun *,*\"*(defun [*] *,*\"*(defun [*]\"*")))
	   (setq lst (separa<->palabras linea '(" " "(" "\""))
		 pos (vl-position "defun" lst)
		 nbref (nth (1+ pos) lst)
	   )
	   (if lstDefuns
	     (if (not (vl-some ; comprobamos cada defun acumulada
			'(lambda (v)
			   (if (and (= (car v) nbref) (/= nbref "defun")); si la defun recien leída coincide con alguna de las encontradas anteriormente
			     (if (setq lr (assoc nbref lstRepets))
			       (setq lstRepets (subst (append lr (list nmarch)) lr lstRepets))
			       (setq lstRepets (append lstRepets (list (append v (list nmarch)))))
			     )
			   )
			 )
			lstDefuns
		      )
		 )
	       (setq lstDefuns (append lstDefuns (list (list nbref nmarch))))
	     )
	     (setq lstDefuns (append lstDefuns (list (list nbref nmarch))))
	   )
	  )
	  ((wcmatch linea "*(load *\")*")
	   (setq lst (separa<->palabras linea '(" " "(" "\"")))
	   (foreach v lst
	     (if dale
	       (setq dale
		      (if (and
			    (not (member (strcase v T) (list "acad2021.lsp" "acad2021doc.lsp")))
			    (or 
			      (= (length (setq lst1 (separa<->palabras v '(".")))) 1)
			      (member (strcase (cadr lst1) T) extens)
			    )
			  )
			(escrutArch v)
		      )
		     dale nil
	       )
	       (if (= (strcase v T) "load")
		 (setq dale T)
	       )
	     )
	   )
	  )
	)
      )
    )
    (if arch (close arch))
  )
  
  (setq lstLsps (list "acad2021.lsp" "acad2021doc.lsp" "acadddd.lsp") extens '("lsp"))
  (foreach lsp lstLsps
    (if (and (findfile lsp) (setq arch (open (setq nmarch (findfile lsp)) "r")))
      (escrutArch nmarch)
    )
  )
  (if arch (close arch))
  (setq i 0)
  (while (setq nmarch (vl-registry-read (strcat "HKEY_CURRENT_USER\\" (vlax-product-key) "\\Profiles\\" (getvar "CPROFILE") "\\Dialogs\\Appload\\Startup") (strcat (itoa (setq i (1+ i))) "StartUp")))
    (escrutArch nmarch)
  )		      
  (if lstRepets
    (if (setq arch (open (setq nmarch (strcat (VL-REGISTRY-READ "HKEY_CURRENT_USER\\Software\\Microsoft\\Windows\\CurrentVersion\\Explorer\\Shell Folders" "Personal") "\\informe.txt")) "w"))
      (foreach lr lstRepets
	(princ (strcat (if (not tit) (setq tit "FUNCTIONS DEFINED MULTIPLE TIMES:\n") "") "\n    Function NAME \'" (car lr) "\' in:\n") arch)
	(foreach path (cdr lr)
	  (princ (strcat "\t" path "\n") arch)
	)
      )
    )
  )
  (if arch (progn (close arch) (startapp "notepad" nmarch)))
  (princ)
)

If after trying this nothing different comes out, then the problem isn't due to overlapping code.

In that case, I would look at the system variables and any reactors your LISPs generate when loading.

Edited August 18 by GLAVCVS
Improvement for unlimited nesteds 'load'

August 16

41 minutes ago, GLAVCVS said:

If after trying this nothing different comes out, then the problem isn't due to overlapping code.

In that case, I would look at the system variables and any reactors your LISPs generate when loading.

Thanks for the help!

I think the problem isn't due to overlapping code.
I will check the system variables and all the reactors.

August 17

Edited:

See if this works.

I have put the other routines as sub routines (LM:Unformat and DoUnformatTable).

Changed the text modifying about so it uses entmod instead of vla (personal preference)

Try it and see if it works - if it does then the unformat part (Lee Macs) is working as expected (it usually does) and there is something you'll be wanting to look at in the code you added.

(defun c:UNFORMAT ( / ss ssl cnt en xxobj otyp txr ntx MyText)

;;;;;;;;;;;;; mAssoc;;;;;;;;;;;;;;;;;;;;;;;;;;;
  (defun mAssoc ( key lst / result ) ;; Lee Mac
    (foreach x lst
      (if (= key (car x))
        (setq result (cons (cdr x) result))
      )
    )
    (reverse result)
  )
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; UnFormat MText, MLeader, Table - strip formatting contol codes from texts
;
; based on Lee Mac's UnFormat string - www.lee-mac.com/unformatstring.html
; CAD Studio, 2018, www.cadstudio.cz  www.cadforum.cz
;
;
(vl-load-com)

;;-------------------=={ UnFormat String }==------------------;;
;;                                                            ;;
;;  Returns a string with all MText formatting codes removed. ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  str - String to Process                                   ;;
;;  mtx - MText Flag (T if string is for use in MText)        ;;
;;------------------------------------------------------------;;
;;  Returns:  String with formatting codes removed            ;;
;;------------------------------------------------------------;;


;;SP ASSUMING LEE MAC PART WORKS. IT USUALLY DOES.


  (defun LM:UnFormat ( str mtx / _replace rx )

    (defun _replace ( new old str )
        (vlax-put-property rx 'pattern old)
        (vlax-invoke rx 'replace str new)
    )
    (if (setq rx (vlax-get-or-create-object "VBScript.RegExp"))
        (progn
            (setq str
                (vl-catch-all-apply
                    (function
                        (lambda ( )
                            (vlax-put-property rx 'global     actrue)
                            (vlax-put-property rx 'multiline  actrue)
                            (vlax-put-property rx 'ignorecase acfalse) 
                            (foreach pair
                               '(
                                    ("\032"    . "\\\\\\\\")
                                    (" "       . "\\\\P|\\n|\\t")
                                    ("$1"      . "\\\\(\\\\[ACcFfHLlOopQTW])|\\\\[ACcFfHLlOopQTW][^\\\\;]*;|\\\\[ACcFfHLlOopQTW]")
                                    ("$1$2/$3" . "([^\\\\])\\\\S([^;]*)[/#\\^]([^;]*);")
                                    ("$1$2"    . "\\\\(\\\\S)|[\\\\](})|}")
                                    ("$1"      . "[\\\\]({)|{")
                                )
                                (setq str (_replace (car pair) (cdr pair) str))
                            )
                            (if mtx
                                (_replace "\\\\" "\032" (_replace "\\$1$2$3" "(\\\\[ACcFfHLlOoPpQSTW])|({)|(})" str))
                                (_replace "\\"   "\032" str)
                            )
                        )
                    )
                )
            )
            (vlax-release-object rx)
            (if (null (vl-catch-all-error-p str))
                str
            )
        )
    )
  ) ;; End LM:Unformat
;-----------------
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  (defun doUnformatTable (table / rowCounter colCounter)
    (setq rowCounter (vla-Get-Rows table))
    (repeat rowCounter
      (setq rowCounter (1- rowCounter))
      (setq colCounter (vla-Get-Columns table))
      (repeat colCounter
        (setq colCounter (1- colCounter))
        (setq cellType (vla-GetCellType table rowCounter colCounter))
        (if (= cellType acTextCell)(progn
          (setq cellText (vla-GetText table rowCounter colCounter))
          (if (/= cellText "")
            (vla-SetText table rowCounter colCounter (LM:UnFormat cellText T)))
        )) ; end if, end if
      ) ; rep
    ) ; rep
  )
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; End Sub routines


  (princ "\nSelect MTEXTs/DIMENSIONs/MLEADERs/TABLEs: ")
  (setq ss (ssget '((0 . "MTEXT,DIMENSION,MULTILEADER,ACAD_TABLE"))))
  (if ss
    (progn
      (setq acount 0)
      (while (< acount (sslength ss))
        (setq ed (ssname ss acount))
        (if (or
            (equal (assoc 0 (entget ed)) '(0 . "MTEXT"))
            (equal (assoc 0 (entget ed)) '(0 . "DIMENSION"))
            (equal (assoc 0 (entget ed)) '(0 . "MULTILEADER"))
          ) ; endor
          (progn
            (setq Mytexts (mAssoc 1 (entget ed)))
            (foreach n Mytexts
              (entmod (subst (cons 1 (lm:Unformat n T)) (cons 1 n) (entget ed)) )
            )
            (setq Mytexts (mAssoc 3 (entget ed))) ;; extend mtexts
            (foreach n Mytexts
              (entmod (subst (cons 3 (lm:Unformat n T)) (cons 3 n) (entget ed)) )
            )
          ) ; end progn mtext
          (progn ; tables
            ((= otyp "ACAD_TABLE")(doUnformatTable (vlax-ename->vla-object ed))) ; AcDbTable
          )
        )
        (setq acount (+ acount 1))
      ) ; end while
    ) ; end progn, ss
  ) ; end if ss
)

Edited August 17 by Steven P

Sign In

UnFormat.lsp does not work in Autocad 2021

Recommended Posts

Nikon

Top Posters In This Topic

Popular Days

Top Posters In This Topic

Popular Days

Popular Posts

GLAVCVS

Steven P

Steven P

Posted Images

ronjonp

Nikon

Steven P

SLW210

GLAVCVS

Nikon

GLAVCVS

Nikon

Steven P

Nikon

Steven P

GLAVCVS

GLAVCVS

Nikon

GLAVCVS

Nikon

GLAVCVS

Nikon

Steven P

Join the conversation

GLAVCVS

Steven P

Steven P

Tutorials

Forums

Activity