annotative text style Help me create a annotative dimension style and text style style

Sunday at 05:13 PM

Dear All,

im trying create a annotative dimension style and text style style . annotation text style link to annotation dimstyle . create text style and dimethyl but annotative symbole not shown in dimension style and also text style )DIM-100 & DIM-200 is annotative dimension style)

  (defun c:TEST ()
  (setvar "cmdecho" 0)
  (setvar "expert" 0)
  (command "undo" "be")
  (princ "\nFunction: Quickly create new dimension styles.\n")


(if (not (tblsearch "STYLE" "STANDARD"))
    (command "style" "Standard" "txt" "" "1" "" "" "")
  )

(if (not (tblsearch "STYLE" "STANDARD"))
  (command ".-style" "STANDARD" "TXT" "0" "1" "0" "N" "N" "N")
)

  (command "dimadec"  "2"
           "dimalt"   "off"
           "dimalttz" "1"
           "dimaltu"  "2"
           "dimassoc" "2"
           "dimasz"   "1"
           "dimatfit" "3"
           "dimaunit" "0"
           "dimazin"  "0"
           "dimblk"   "_ARCHTICK"        
           "dimcen"   "0"
           "dimclrd"  "0"
           "dimclre"  "0"
           "dimclrt"  "0"
           "dimdec"   "2"
           "dimdle"   "0.00"
           "dimdli"   "0.05"
           "dimdsep"  "."
           "dimexe"   "0.35"
           "dimexo"   "0.35"
           "dimfxlon" "off"
           "dimgap"   "0.5"
           "dimjust"  "0"
           "dimldrblk" "_ARCHTICK"       
           "dimlfac"  "1"
           "dimlunit" "2"
           "dimscale" "1"
           "dimtad"   "1"
           "dimtdec"  "2"
           "dimtfac"  "1"
           "dimtfill" "0"
           "dimtfillclr" "0"
           "dimtih"   "off"
           "dimtix"   "off"
           "dimtmove" "0"
           "dimtofl"  "on"
           "dimtol"   "off"
           "dimtolj"  "1"
           "dimtxsty" "Standard"        
           "dimtxt"   "2.5"
           "dimtzin"  "1"
           "dimupt"   "off"
           "dimzin"   "1"
           )
  (if (not (tblsearch "dimstyle" "TEST-123"))
    (command "dimstyle" "S" "TEST-123")
  )

;; --------------------------------------


(if (not (tblsearch "STYLE" "TEST-100"))
  (command ".-style" "TEST-100" "Calibri" "0" "1" "0" "N" "N" "N")
)


(setvar "DIMTOL" 1)       
(setvar "DIMTM" 0.05)     
(setvar "DIMTP" 0.05)      
(setvar "DIMTXSTY" "TEST-100") 

;; Create or update dimension style
(if (not (tblsearch "dimstyle" "DIM-100"))
  (progn
    (command ".-dimstyle" "S" "DIM-100")
  )

  (command ".-dimstyle" "R" "DIM-100")
)

;; --------------------------------------

(if (not (tblsearch "STYLE" "TEST-200"))
  (command ".-style" "TEST-200" "ARIAL" "0" "1" "0" "N" "N" "N")
)

(setvar "DIMTOL" 1)       
(setvar "DIMTM" 0.10)      
(setvar "DIMTP" 0.10)      
(setvar "DIMTXSTY" "TEST-200") 


(if (not (tblsearch "dimstyle" "DIM-200"))
  (progn
    (command ".-dimstyle" "S" "DIM-200")
  )

  (command ".-dimstyle" "R" "DIM-200")
)

  (command "undo" "e")
  (alert "\nPrompt:\nDimension style creation completed!\n")
  (princ)
)

OPT-2

THIS OPTION TEXT STYLE NOT CRETED IN ANNOTATIVE STYLE AND ONE MORE QUERT I WANT TEST-123 IS NORMAL DIM STYLE

(defun c:TEST (/ oldcmdecho oldexpert)
  (setq oldcmdecho (getvar "cmdecho")
        oldexpert (getvar "expert"))
  (setvar "cmdecho" 0)
  (setvar "expert" 5)
  
  (command "_.undo" "_begin")


  (if (not (tblsearch "STYLE" "Standard"))
    (command "_.-style" "Standard" "txt" "2.5" "" "" "" "")
  )

  (if (not (tblsearch "STYLE" "TEST-100"))
    (command "_.-style" "TEST-100" "Calibri" "2.5" "" "" "" "")
  )

  (if (not (tblsearch "STYLE" "TEST-200"))
    (command "_.-style" "TEST-200" "Arial" "2.5" "" "" "" "")
  )

  (while (> (getvar "cmdactive") 0) (command ""))


  (if (not (tblsearch "DIMSTYLE" "TEST-123"))
    (progn
      (setvar "DIMTOL" 0)
      (setvar "DIMTXSTY" "Standard")
      (command "_.-dimstyle" "_S" "TEST-123")
      (while (> (getvar "cmdactive") 0) (command ""))
    )
  )


  (if (not (tblsearch "DIMSTYLE" "DIM-100"))
    (progn
      (setvar "DIMTOL" 1)
      (setvar "DIMTM" 0.05)
      (setvar "DIMTP" 0.05)
      (setvar "DIMTXSTY" "TEST-100")
      (setvar "DIMTDEC" 2)
      (command "_.-dimstyle" "_S" "DIM-100")
      (while (> (getvar "cmdactive") 0) (command ""))
    )
  )

  ;; DIM-200 - With tolerances
  (if (not (tblsearch "DIMSTYLE" "DIM-200"))
    (progn
      (setvar "DIMTOL" 1)
      (setvar "DIMTM" 0.10)
      (setvar "DIMTP" 0.10)
      (setvar "DIMTXSTY" "TEST-200")
      (setvar "DIMTDEC" 2)
      (command "_.-dimstyle" "_S" "DIM-200")
      (while (> (getvar "cmdactive") 0) (command ""))
    )
  )

  (command "_.undo" "_end")
  (setvar "cmdecho" oldcmdecho)
  (setvar "expert" oldexpert)

  (princ "\nTEST command completed successfully!")
  (princ)
)

Edited Sunday at 09:04 PM by sachindkini

Sunday at 10:26 PM

I think you need to look at Entmake a style whether its a text style or a dimension style rather than trying to override current settings. trying to find a good simple example some else may have one.

Monday at 03:41 AM

Entmake text style.

  (entmake '((0 . "STYLE") (100 . "AcDbSymbolTableRecord") (100 . "AcDbTextStyleTableRecord")
             (2 . "style name here") (70 . 0) (40 . 0.0) (41 . 1.0) (50 . 0.0) (71 . 0) (42 . 1.0)
             (3 . "Arial.ttf") (4 . "")
            )
  )

use setvar for dimstyles nothing will be outputted to command prompt.

(setvar 'DIMADEC 2)
(setvar 'DIMALT "off")

I think @Steven P has dug into this more.

Monday at 11:59 AM

I don't tend to annotative dims as much as perhaps I should but will see what I can dig out

2025-10-29T14:55:42Z

Coming back to this one:

Annotative Text, I find that I have to create the text style and then add the extended data to convert it to annotative text

Handy that this can have an if loop in it and be used to create either normal or annotative if you want to adjust it:

(defun c:MakeAnnoFont ( FontName FontStyle / Height NewFontEnt exdata newent )
  (setq Height 0)
  (setq NewFontEnt (entmakex (list
    '(0 . "STYLE")
    '(100 . "AcDbSymbolTableRecord")
    '(100 . "AcDbTextStyleTableRecord")
    (cons 2 FontName)
    '(70 . 0)
    (cons 40 Height)
    '(41 . 1.0)
    '(50 . 0.0)
    '(71 . 0)
    (cons 42 Height)
    (cons 3 FontStyle) ;; Font style to include suffix e.g. '.ttf' or '.shx'
    '(4 . "")
  ))) ; end entmakex, end list, end setq

;;Add xdata - annotative text
  (regapp "AcadAnnotative")
  (setq exdata
    '((-3 ("AcadAnnotative"
        (1000 . "AnnotativeData")
        (1002 . "{")
        (1070 . 1)
        (1070 . 1)
        (1002 . "}")
      ) ; new extended data—
    ))
  )
  (setq newent (append (entget NewFontEnt) exdata)) ; Appends new data list to entity's list.
  (entmod newent) ; Modifies the entity with the new definition data.

  (princ)
)

I don't use a lot of annotative dimensions to make a LISP worthwhile, but reading this week I think the method is the same, create the dimension and then add the xdata to it afterwards.

Most of my dimension LISPs started off from here:

https://stackoverflow.com/questions/47835301/use-autolisp-to-generate-new-dimension-style

Though from BigAl, I think this one sets all the dimension stuff

; https://www.cadtutor.net/forum/topic/56889-entmake-for-dimension-styles/
; BigAl
; DimStyle Create
;
(defun DSTYLE_DIMSTYLE_CREATE (DSTY$ DSCL# AH$ FSTY$)
  (if (null (tblsearch "dimstyle" DSTY$))
    (progn
      (entmakex
        (list
   (cons 0 "DIMSTYLE")                                           ; Entity Type
   (cons 100 "AcDbSymbolTableRecord")                            ; Subclass marker
   (cons 100 "AcDbDimStyleTableRecord")                          ; Subclass marker
   (cons 2 DSTY$)                                                ; Dimstyle name
   (cons 70 0)                                                   ; Standard flag value
   (cons 3 "")                                                   ; DIMPOST
   (cons 4 "")                                                   ; DIMAPOST
   (cons 5  AH$)                                                 ; DIMBLK
   (cons 6  AH$)                                                 ; DIMBLK1
   (cons 7  AH$)                                                 ; DIMBLK2
   (cons 40 DSCL#)                                               ; DIMSCALE
   (cons 41 0.0937)                                              ; DIMASZ
   (cons 42 0.0937)                                              ; DIMEXO
   (cons 43 0.38)                                                ; DIMDLI
   (cons 44 0.0625)                                              ; DIMEXE
   (cons 45 0.0)                                                 ; DIMRND
   (cons 46 0.0625)                                              ; DIMDLE
   (cons 47 0.0)                                                 ; DIMTP
   (cons 48 0.0)                                                 ; DIMTM
   (cons 140 0.0937)                                             ; DIMTXT
   (cons 141 0.09)                                               ; DIMCEN
   (cons 142 0.0)                                                ; DIMTSZ
   (cons 143 25.4)                                               ; DIMALTF
   (cons 144 1.0)                                                ; DIMLFAC
   (cons 145 0.0)                                                ; DIMTVP
   (cons 146 1.0)                                                ; DIMTFAC
   (cons 147 0.0625)                                             ; DIMGAP
   (cons 71 0)                                                   ; DIMTOL
   (cons 72 0)                                                   ; DIMLIM
   (cons 73 0)                                                   ; DIMTIH
   (cons 74 0)                                                   ; DIMTOH
   (cons 75 0)                                                   ; DIMSE1
   (cons 76 0)                                                   ; DIMSE2
   (cons 77 0)                                                   ; DIMTAD
   (cons 78 3)                                                   ; DIMZIM
   (cons 170 0)                                                  ; DIMALT
   (cons 171 2)                                                  ; DIMALTD
   (cons 172 0)                                                  ; DIMTOFL
   (cons 173 0)                                                  ; DIMSAH
   (cons 174 0)                                                  ; DIMTIX
   (cons 175 0)                                                  ; DIMSOXD
   (cons 176 1)                                                  ; DIMCLRD
   (cons 177 1)                                                  ; DIMCLRE
   (cons 178 2)                                                  ; DIMCRRT
   (cons 270 4)                                                  ; DIMUNIT
   (cons 271 4)                                                  ; DIMDEC
   (cons 272 4)                                                  ; DIMTDEC
   (cons 273 2)                                                  ; DIMALTU
   (cons 274 2)                                                  ; DIMALTTD
   (cons 275 0)                                                  ; DIMAUNIT
   (cons 276 2)                                                  ; DIMFRAC
   (cons 277 4)                                                  ; DIMLUNIT
   (cons 279 2)                                                  ; DIMTMOVE
   (cons 280 0)                                                  ; DIMJUST
   (cons 281 0)                                                  ; DIMSD1
   (cons 282 0)                                                  ; DIMSD2
   (cons 283 1)                                                  ; DIMTOLJ
   (cons 284 0)                                                  ; DIMTZIN
   (cons 285 0)                                                  ; DIMALTZ
   (cons 286 0)                                                  ; DIMALTTZ
   (cons 287 5)                                                  ; DIMFIT
   (cons 288 0)                                                  ; DIMUPT
   (cons 340 (tblobjname "style" FSTY$))                         ; DIMTXSTY 
   (cons 342 (cdr (assoc 330 (entget (tblobjname "block" AH$))))); DIMLDRBLK
   (cons 343 (cdr (assoc 330 (entget (tblobjname "block" AH$))))); DIMLDRBLK1
   (cons 344 (cdr (assoc 330 (entget (tblobjname "block" AH$))))); DIMLDRBLK2
        )
      )
    )
  )

And I'll give you 'Jeff' which has a better description of the one above

Jeff just adjusts dimension font style, text height, and colours. Arrows are set at 2x font height I think - from the stackoverflow link above

(defun c:jeff ( / DimStyleName DSN FontStyleName FSN FontHeight TxtCol LinCol Col TxtPrecision TxtPrec) ;;change dimension style

;;Dimension Style
  (princ "\nEnter Dimension style Name ")(princ (tableSearch "dimstyle"))
  (setq DimStyleName (getvar "dimstyle"))
  (setq DSN (getstring (strcat ": (" DimStyleName "): ") t))
  (if (or (= DSN nil)(= DSN ""))
    (setq DimStyleName DimStyleName)
    (setq DimStyleName DSN)
  ) 
  (princ DimStyleName)

;;Font Style
  (princ  "\nEnter Font style Name ")(princ (tableSearch "style"))
;;  (setq FontStyleName (nth 0 (tableSearch "style")))
  (setq FontStyleName (getvar "textstyle"))
  (setq FSN (getstring (strcat " (" FontStyleName "): ") t))
  (if (or (= FSN nil)(= FSN ""))
    (setq FontStyleName FontStyleName)
    (setq FontStyleName FSN)
  )
  (princ FontStyleName)

;;Font Height
  (setq FontHeight 2.5) ;; How to get this from dimstyle selected above
  (setq FontHght (getreal (strcat "\nEnter Font Height [" (rtos FontHeight)"]: ")))
  (if (or (= FontHght nil)(= FontHght ""))
    (setq FontHeight FontHeight)
    (setq FontHeight FontHght)
  )
  (princ FontHeight)

;;Colours
  (setq TxtCol 0) ;Text. 0: By Layer, 256: ByBlock
  (setq Col (getint (strcat "\nEnter Text Colour Code (0: ByLayer, 256: ByBock) [" (rtos TxtCol)"]: ")))
  (if (or (= Col nil)(= Col ""))
    (setq TxtCol TxtCol)
    (setq TxtCol Col)
  )
  (princ TxtCol)
  (setq LinCol 0) ;Lines. 0: By Layer, 256: ByBlock
  (setq Col (getint (strcat "\nEnter Lines Colour Code (0: ByLayer, 256: ByBock) [" (rtos LinCol)"]: ")))
  (if (or (= Col nil)(= Col ""))
    (setq LinCol LinCol)
    (setq LinCol Col)
  )
  (princ LinCol)

;;Precision
  (setq TxtPrecision 4) ; number of decimal places  ;; How to get this from dimstyle selected above
  (setq TxtPrec (getint (strcat "\nEnter Decimal Places) [" (rtos TxtPrecision) "]: ")))
  (if (or (= TxtPrec nil)(= TxtPrec ""))
    (setq TxtPrecision TxtPrecision)
    (setq TxtPrecision TxtPrec)
  )
  (princ TxtPrecision)(princ " DP")

  (setq DimensionScale (/ FontHeight 2.5))
  (jeff1 DimStyleName FontStyleName FontHeight TxtCol LinCol TxtPrecision DimensionScale)
  (princ)
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun jeff1 ( DimStyleName FontName FontHeight TxtCol LinCol TxtPrecision DimensionScale / )
;;Sub Routines
  (defun mytextstyle ( myfont / mytextstyle fontcount fontlist) ;;check textstyle is loaded
  ;;Font Style Lists
  ;;Fontname Height WidthFactor ObliqueAngle Backwards UpsideDown
    (setq fontstyles (list
      (list "Standard" "Arial" "0.0000" "1.0000" "0" "No" "No")
      (list "romans" "romans.shx" "0.0000" "1.0000" "0" "No" "No")
;;Add your own font definitions here
    ));end fontstyles list

   (if (member myfont (tableSearch "style"))
    (princ "Font Is Loaded")
    (progn ; Font isn't loaded
      (setq fontcount 0)
      (while (< fontcount (length fontstyles))
        (if (= (strcase (nth 0 (nth fontcount fontstyles))) (strcase myfont))
          (progn ;font style is loaded
            (setq fontlist fontcount) ;;font style exists
          ) ; end progn
        ) ;end if
        (setq fontcount (+ 1 fontcount))
      )
  
      (if (= fontlist nil)
        (progn ;;if font is not defined above or loaded
          (alert "Font style needs loading. Please edit it")
          (command "Style" myfont "romans.shx" "0.0000" "1.0000" "0" "No" "No" "No")
          (initdia)
          (command "style")
        ) ;end progn
        (progn
          (command "style" (nth 0 (nth fontlist fontstyles)) (nth 1 (nth fontlist fontstyles))
                           (nth 2 (nth fontlist fontstyles)) (nth 3 (nth fontlist fontstyles))
                           (nth 4 (nth fontlist fontstyles)) (nth 5 (nth fontlist fontstyles))
                           (nth 6 (nth fontlist fontstyles)) (nth 7 (nth fontlist fontstyles))
          ) ;end command
        ) ;end progn
      ) ;end if
    ) ;end progn
    );end if
    (setq mystyle myfont) ;;text font style.. if anything else check if style is loaded into drawing here
    mystyle
  )
;;End Sub Routines

  (mytextstyle FontName) ;; Check Font exists else make it

;;Full list of dimension variables.
;;Change all or none as required, save and existing style to update
;;NOTE: BYBLOCK and other texts to be numbers?
;;https://help.autodesk.com/view/ACDLTM/2016/ENU/?guid=GUID-30F44A49-4250-42D1-AEF2-5E2914ADB02B
;;         List     value    ;; Default       ;;Description
 (setvar "DIMADEC"  TxtPrecision)  ;; 0       ;;Angular Dimension Decimal Places
;  (setvar "DIMALT"    0)    ;; 0              ;;Control of alternative units 0 - Off 1 - On
  (setvar "DIMALTD"   TxtPrecision)    ;; 2 / 3          ;;Alternative Units Decimal Places
;  (setvar "DIMALTF" 0.0394) ;; 25.4 / 0.0394  ;;Alternative Units Scale Factor
;;(setvar "DIMALTMZF")      ;;                ;;Alternate sub-zero factor for metric dimensions - Unknown variable
;;(setvar "DIMALTMZS")      ;;                ;;Alternate sub-zero suffix for metric dimensions - Unknown variable
;  (setvar "DIMALTRND" 0.00) ;; 0.00           ;;Alternate units rounding value
;  (setvar "DIMALTTD"  3)    ;; 2 / 3          ;;Alternative Units Tolerance Decimal Places
;  (setvar "DIMALTTZ"  0)    ;; 0              ;;Alternate tolerance zero suppression
;  (setvar "DIMALTU"   2)    ;; 2              ;;Alternative Units Units
;  (setvar "DIMALTZ"   0)    ;; 0              ;;Alternate unit zero suppression
;  (setvar "DIMAPOST" "")    ;; ""             ;;Prefix and suffix for alternate text
;  (setvar "DIMARCSYM" 0)    ;; 0              ;;Arc Length Dimension Arc Symbol
  (setvar "DIMASZ" FontHeight) ;; 0.18 / 2.5  ;;Dimension Line and Leader Line Arrow Heads size
;  (setvar "DIMATFIT"  3)    ;; 3              ;;Arrow and text fit if distance is too narrow for both
;  (setvar "DIMAUNIT"  0)    ;; 0              ;;Angular unit format
;  (setvar "DIMAZIN"   0)    ;; 0              ;;Angular Dimension Depresses leading zeros
;  (setvar "DIMBLK"  ".")    ;; "."            ;;Arrow block name "." for closed flled else as properties
;  (setvar "DIMBLK1" ".")    ;; "."            ;;First arrow block name "." for closed flled else as properties
;  (setvar "DIMBLK2" ".")    ;; "."            ;;Second arrow block name "." for closed flled else as properties
  (setvar "DIMCEN" FontHeight) ;; 0.09 / 2.5  ;;Drawing centre mark for radius or diameter dimensions
  (setvar "DIMCLRD" LinCol) ;; 0              ;;Colours - Lines, ArrowHeads, Dimension Lines 0: ByLayer, 256 ByBlock
  (setvar "DIMCLRE" LinCol) ;; 0              ;;Colours - Extension Lines, Centre Marks Colours 0: ByLayer, 256 ByBlock
  (setvar "DIMCLRT" TxtCol) ;; 0              ;;Colours - Dimension Text Colour 0: ByLayer, 256 ByBlock
  (setvar "DIMDEC"  TxtPrecision)  ;; 0       ;;Dimension Decimal Places
;  (setvar "DIMDLE"    0)    ;; 0.0000         ;;Dimension Line extension with oblique strokes instead of arrows
;  (setvar "DIMDLI"    4)    ;; 3.75           ;;Dimension Baseline Dimension Spacing
  (setvar "DIMDSEP" ".")    ;; .              ;;Decimal separator
  (setvar "DIMEXE" (/ Fontheight 2)) ;; 0.18 / 1.25    ;;Extension Line Extension distance
  (setvar "DIMEXO" (/ Fontheight 4)) ;; 0.0625 / 0.625 ;;Extension Line Offset
;  (setvar "DIMFRAC"   0)    ;; 0              ;;Dimension Fraction Format
;  (setvar "DIMFXL" 1.00)    ;; 1              ;;Fixed Extension Line
;  (setvar "DIMFXLON"  0)    ;; 0              ;;Enable Fixed Extension Line 0 - Off 1 - On
  (setvar "DIMGAP" (/ FontHeight 4)) ;; 0.09 / 0.625   ;;Dimension gap between text and arrow 
  (setvar "DIMJOGANG" (* pi (/ 45 180.0))) ;; ;;Radius dimension jog angle.. radians?
;  (setvar "DIMJUST"   0)    ;; 0              ;;Justification of text on dimension line
  (setvar "DIMLDRBLK" ".")  ;; "."            ;;Leader block name "." for closed flled else as properties
;  (setvar "DIMLFAC" 1.00)   ;; 1              ;;Linear unit scale factor
;  (setvar "DIMLIM"    0)    ;; 0              ;;Generate dimension limits 0 - Off 1 - On
  (setvar "DIMLTEX1" "BYBLOCK")    ;;  "."    ;;Linetype extension line 1
  (setvar "DIMLTEX2" "BYBLOCK")    ;;  "."    ;;Linetype extension line 2
  (setvar "DIMLTYPE" "BYBLOCK")    ;;  "."    ;;Dimension linetype
;  (setvar "DIMLUNIT"  2)    ;; 2              ;;Dimension Units (except angular) - number type
;  (setvar "DIMLWD"   -2)    ;; -2             ;;Dimension Line Lineweights
;  (setvar "DIMLWE"   -2)    ;; -2             ;;Extension Line Line Weight
;;(setvar "DIMMZF")         ;;                ;;Sub-zero factor for metric dimensions - Unknown variable
;;(setvar "DIMMZS")         ;;                ;;Sub-zero suffix for metric dimensions - Unknown variable
;  (setvar "DIMPOST" "")     ;; ""             ;;Prefix and suffix for dimension text
;  (setvar "DIMRND"   0)     ;; 0              ;;Dimension Round distance to nearest n
;  (setvar "DIMSAH"   0)     ;; 0              ;;Separate arrow blocks 0 - Off 1 - On
;  (setvar "DIMSCALE" 1)     ;; 1              ;;Dimension Scale Factor
;  (setvar "DIMSD1"   0)     ;; 0              ;;Suppress the first dimension line 0 - Off 1 - On
;  (setvar "DIMSD2"   0)     ;; 0              ;;Suppress the second dimension line 0 - Off 1 - On
;  (setvar "DIMSE1"   0)     ;; 0              ;;Suppress the first extension line 0 - Off 1 - On
;  (setvar "DIMSE2"   0)     ;; 0              ;;Suppress the second extension line 0 - Off 1 - On
;  (setvar "DIMSOXD"  0)     ;; 0              ;;Suppress outside dimension lines
;  (setvar "DIMTAD"   0)     ;; 0              ;;Dimension Text Vertical distance
;  (setvar "DIMTDEC"  4)     ;; 4              ;;Tolerance decimal places
;  (setvar "DIMTFAC"  1)     ;; 1              ;;Dimension text scale factor of fractions relative to text height
;  (setvar "DIMTFILL" 0)     ;; 0              ;;Text background enabled
;  (setvar "DIMTFILLCLR" 0)  ;; 0              ;;Text background color 0: ByLayer, 256 ByBlock
;  (setvar "DIMTIH"   0)     ;; 0              ;;Text inside extensions is horizontal 0 - Off 1 - On
;  (setvar "DIMTIX"   0)     ;; 0              ;;Place text inside extensions 0 - Off 1 - On
;  (setvar "DIMTM"    0)     ;; 0              ;;Dimension Minus tolerance distance when used with dimtol, or dimlim
;  (setvar "DIMTMOVE" 0)     ;; 0              ;;Text movement
;  (setvar "DIMTOFL"  0)     ;; 0              ;;Force line inside extension lines 0 - Off 1 - On
;  (setvar "DIMTOH"   1)     ;; 1              ;;Text outside horizontal 0 - Off 1 - On
;  (setvar "DIMTOL"   0)     ;; 0              ;;Tolerance dimensioning 0 - Off 1 - On
;  (setvar "DIMTOLJ"  1)     ;; 0              ;;Tolerance vertical justification
;  (setvar "DIMTP"    0)     ;; 0              ;;Dimension Plus tolerance distance when used with dimtol, or dimlim
;  (setvar "DIMTSZ" 0.00)    ;; 0              ;;Tick size
;  (setvar "DIMTVP" 0.00)    ;; 0              ;;Text vertical position
  (setvar "DIMTXSTY" FontName)     ;; Font    ;;Text style
  (setvar "DIMTXT" FontHeight)     ;; 0.18 / 2.5   ;;Dimension text Height
;;(setvar "DIMTXTDIRECTIONOff" 0)  ;;         ;;Dimension text direction 1 or 0 - NOT SURE IF THIS WORKS
;  (setvar "DIMTZIN"  8)     ;; 8              ;;Suppresses leading zeros in tolerance values
;  (setvar "DIMUPT"   0)     ;; 0              ;;User positioned text 0 - Off 1 - On
;  (setvar "DIMZIN"   8)     ;; 8              ;;Suppresses leading zeroes

;;Set Dimstyle named above to this list
  (setq dimstylelist (tableSearch "dimstyle"))
  (if (= (member DimStyleName dimstylelist) nil)
    (command "dimstyle" "s" DimStyleName)
    (command "dimstyle" "s" DimStyleName "Y")
  )
    (princ)
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Hope that sets you on your way a little

Edit: Last snippet. If you want to get the entity name of a font style, which you can apply to the add xdata portion from my first code to add annotative to an existing font.

(defun c:GetTextStyle ( FontName / )
  (Entget (tblobjname "style" FontName))
;;(entget (tblobjname "Style" FontName) '("AcadAnnotative")) ;; Lists registered app AcadAnnotative entries
)

Edited 5 minutes ago by Steven P

Sign In

annotative text style Help me create a annotative dimension style and text style style

Recommended Posts

sachindkini

BIGAL

mhupp

Steven P

Steven P

Join the conversation

Tutorials

Forums

Activity