Custom DCL List box and radio buttons loses focus and values.

[BIGAL]

I have coded a dcl as per image but I can not get the list box answer I get the radio buttons as a list which is what I want. If ran as source code the listbox lsp works fine returning the items selected as a list. I am sure it is something very simple I am doing wrong. It will also help with a possible other post to know the answer.

 

; Big thanks to Alan J. Thompson, 09.23.08 / 05.17.10 (rewrite)
; For the original list box Listslect.lsp
; Modified by AlanH May 2026 to also have edit boxes
  

(defun AH:xxxxxx1 ( / anslst1 anslts2 dcl_id key_lst keynum num x y)

(setq fo (open (setq fn "D:\\acadtemp\\xxxxxx.dcl") "W"))
(foreach x (list 
  "roslist_select : dialog { "
  "label =   \"Layout choice\"  ; "
  ": row { "
  ": column { "
  ": list_box { "
  "label = \"Please choose\" ;"
  "key = \"lst1\" ;"
  "allow_accept = false ; "
  "height = 15  ; "
  "width = 25 ; "
  "multiple_select = true ; }"
  "}"
  " : boxed_column {"
  (strcat " label =" (chr 34) (nth 0 lst2) (chr 34) " ;")
  " width =25 ;"
  )
  (write-line x fo)
)

(setq num (/ (- (length lst2) 1) 4))
(setq x 0)
(setq y 0)
(repeat num
    (write-line "spacer_1 ;" fo)
    (write-line ": edit_box {" fo)
    (setq keynum (strcat "key" (rtos (setq y (+ Y 1)) 2 0)))
    (write-line (strcat "    key = " (chr 34) keynum (chr 34) ";") fo)
    (write-line (strcat " label = " (chr 34) (nth (+ x 1) lst2) (chr 34)  ";") fo)
    (write-line (strcat "     edit_width = " (rtos (nth (+ x 2) lst2) 2 0) ";") fo)
    (write-line (strcat "     edit_limit = " (rtos (nth (+ x 3) lst2) 2 0) ";") fo)
    (write-line "   is_enabled = true ;" fo)
    (write-line "   allow_accept=false ;" fo)
    (write-line "    }" fo)
	(setq x (+ x 4))
)

(write-line "spacer ; " fo)
(write-line "ok_cancel ;" fo)
(write-line "}" fo)
(write-line "}" fo)
(write-line "}" fo)
(close fo)

(setq dcl_id (load_dialog fn))
  (if (not (new_dialog "roslist_select" dcl_id))
    (exit)
  )  
  (start_list "lst1")
  (mapcar (function add_list) lst1)
  (end_list)
  (set_tile "lst1" "0")
  (setq x 0)
  (setq y 0)
  (setq anslst2 '())
  (repeat num
    (setq keynum (strcat "key" (rtos (setq y (+ Y 1)) 2 0)))
    (setq key_lst (cons keynum key_lst))
    (set_tile keynum (nth (setq x (+ x 4)) lst2))
  )
 ; (mode_tile "key1" 2)
 (action_tile "accept" "(mapcar '(lambda (x) (setq anslst2 (cons (get_tile x) anslst2))) key_lst)(done_dialog)")
 (action_tile "lst1" "(setq anslst1 $value)")
 (action_tile "cancel" "(done_dialog)")
  (start_dialog)
  (unload_dialog dcl_id)
 ; (vla-file-delete fn)
)

(setq lst1 (cons "New layout" (layoutlist)))
(setq lst2 (list "Enter values " "Date to add" 15 14 "" "Drawn by" 15 14 "" "Checked by" 15 14 "" "Approved by" 15 14 ""))

(AH:xxxxxx1)

(if (= anslst1 nil)(alert "anslst1 is nil")(princ anslst1))
(princ "\n")
(princ anslst2)

  ; anslst1 holds lst1 select values
  ; anslst2 holds the getval values

[rlx]

you have no action_tile assigned to your edit_boxes key1 ... key4

also anslst1 anslts2 have been declared local in your defun so values are not exposed outside your defun

 

; For the original list box Listslect.lsp
; Modified by AlanH May 2026 to also have edit boxes
  

(defun AH:xxxxxx1 ( / fo fn  dcl_id key_lst keynum num x y) ;; anslst1 anslts2
  ;(setq fo (open (setq fn "D:\\acadtemp\\xxxxxx.dcl") "W"))
  (setq fo (open (setq fn "C:\\temp\\xxxxxx.dcl") "W"))
  (foreach x
           (list
             "roslist_select : dialog {label=\"Layout choice\";"
             ": row { "
             "  : column { "
             "    : list_box {label=\"Please choose\";"
             "      key=\"lst1\";allow_accept=false;height=15;width=25;ultiple_select=true;}"
             "}"
             " : boxed_column {"
                 (strcat "label=" (chr 34) (nth 0 lst2) (chr 34) " ;")
                 " width =25;"
             )
    (write-line x fo)
  )
  (setq num (/ (- (length lst2) 1) 4))
  (setq x 0)
  (setq y 0)
  (repeat num
    (write-line "spacer_1 ;" fo)
    (write-line ": edit_box {" fo)
    (setq keynum (strcat "key" (rtos (setq y (+ Y 1)) 2 0)))
    (write-line (strcat "    key = " (chr 34) keynum (chr 34) ";") fo)
    (write-line (strcat " label = " (chr 34) (nth (+ x 1) lst2) (chr 34)  ";") fo)
    (write-line (strcat "     edit_width = " (rtos (nth (+ x 2) lst2) 2 0) ";") fo)
    (write-line (strcat "     edit_limit = " (rtos (nth (+ x 3) lst2) 2 0) ";") fo)
    (write-line "   is_enabled = true ;" fo)
    (write-line "   allow_accept=false ;" fo)
    (write-line "    }" fo)
    (setq x (+ x 4))
  )
  (write-line "spacer ; " fo)
  (write-line "ok_cancel ;" fo)
  (write-line "}" fo)
  (write-line "}" fo)
  (write-line "}" fo)
  (close fo)

  (setq dcl_id (load_dialog fn))
  (if (not (new_dialog "roslist_select" dcl_id))(exit))  
  (start_list "lst1") (mapcar (function add_list) lst1) (end_list)
  (set_tile "lst1" "0")
  (setq x 0)
  (setq y 0)
  (setq anslst2 '())
  (repeat num
    (setq keynum (strcat "key" (rtos (setq y (+ Y 1)) 2 0)))
    (setq key_lst (cons keynum key_lst))
    (set_tile keynum (nth (setq x (+ x 4)) lst2))
  )
  ; (mode_tile "key1" 2)
  ;(action_tile "accept" "(mapcar '(lambda (x) (setq anslst2 (cons (get_tile x) anslst2))) key_lst)(done_dialog)")
  (action_tile "accept" "(read_tiles key_lst)(done_dialog)")
  (action_tile "lst1" "(setq anslst1 $value)")
  (action_tile "cancel" "(done_dialog)")
  (start_dialog)
  (unload_dialog dcl_id)
  ; (if (setq fn (findfile fn)) (startapp "notepad" fn))
  ; (vla-file-delete fn)
  (princ)
) ;;; end defun

(defun read_tiles (key_lst) (foreach key key_lst (setq anslst2 (cons (cons key (get_tile key)) anslst2))))

;;; hit & run
(setq lst1 (cons "New layout" (layoutlist)))
(setq lst2 (list "Enter values " "Date to add" 15 14 "" "Drawn by" 15 14 "" "Checked by" 15 14 "" "Approved by" 15 14 ""))

(AH:xxxxxx1)

(if (= anslst1 nil)(alert "anslst1 is nil")(princ anslst1))
(princ "\n")
(princ anslst2)

  ; anslst1 holds lst1 select values
  ; anslst2 holds the getval values

 

Edited yesterday at 01:11 PM by rlx

[BIGAL]

Thanks for the reply.

 

I fixed the typo we all do it." ;ultiple_select=true;"

 

It seems that using a defun for the (Action_tile lst1) seemed to work, the return is a string so added a convert to list at end so get ("0" "1") etc as answer the number in layout list as a string. I also removed the double cons so only get the actual answers as a list.

 

As this is just a start code for updating title blocks in layouts the Anslstx variables will be localised. As I said about the added defun the anslst2 was working even when localised.

 

Next step is adding some radio buttons to the dcl but hopefully that will not cause problems.

 

So thanks again.