Whats wrong with this lisp?

[asos2000]

Whats wrong with this lisp?

 

(defun c:MMNT ()

(vl-load-com)

(if (and (setq ent (car (entsel "\nSelect Object: ")))

(setq pt (getpoint "\nPick a Point: ")))

(progn

(setq obj (vlax-ename->vla-object ent))

(if (vlax-property-available-p obj 'momentOfInertia)

(progn ; SUBPROGN

(setq MNT (rtos (vla-get-MomentOfInertia obj) 2 4))

(entmakex (list (cons 0 "TEXT")

(cons 10 pt)

(cons 40 (getvar "TEXTSIZE"))

(cons 1 MNT)

) ; end LIST

) ; end entmakex

) ; end SUBPROGN

(princ "\n** Invalid Object Selected **")

) ;END IF

) ; END PROGN

) ; END IF

(princ)

)

 

this line doesnt give any result

(setq MNT (rtos (vla-get-MomentOfInertia obj) 2 4))

[lpseifert]

Maybe because the (vla-get-MomentOfInertia... returns a variant, not a real

try this (not a whole lot of testing)

(defun c:MMNT ()
(vl-load-com)
(if (and (setq ent (car (entsel "\nSelect Object: ")))
(setq pt (getpoint "\nPick a Point: ")))
(progn
(setq obj (vlax-ename->vla-object ent))
(if (vlax-property-available-p obj 'momentOfInertia)
(progn ; SUBPROGN
(setq var (vla-get-MomentOfInertia obj)
     sa (vlax-variant-value var)
     lst (vlax-safearray->list sa)
     MNT (strcat (rtos (car lst) 2 4) " "(rtos (cadr lst) 2 4 ))
         )
(entmakex (list (cons 0 "TEXT")
(cons 10 pt)
(cons 40 (getvar "TEXTSIZE"))
(cons 1 MNT)
) ; end LIST
) ; end entmakex
) ; end SUBPROGN
(princ "\n** Invalid Object Selected **")
) ;END IF
) ; END PROGN
) ; END IF
(princ)
) 

[rkmcswain]

Step through the code and inspect the return values....

 

(vla-get-MomentOfInertia obj) returns a variant and (rtos) expects a real number.

 

(vlax-safearray->list 
  (vlax-variant-value 
     (vla-get-MomentOfInertia obj)
  )
) 
;;;will return the value in list form. 
;;;Then you can format this as desired.

 

 

EDIT: lpseifert has got it for you already....

[asos2000]

NOT WORKING

Command: MMNT

Select Object:

Pick a Point: _.layer

Current layer: "0"

Enter an option

[lpseifert]

somehow during a copy/paste something was lost... try it now

[asos2000]

Its working

Its in one line i'll divide into 2 lines

Thanks

[Lee Mac]

You can avoid the variant with:

 

(vlax-get obj 'MomentofInteria)

 

Lee

[asos2000]

LEE

 

I'll give a try and tell you

what shall I do is,

replace

(vla-get-MomentOfInertia obj)

with

(vlax-get obj 'MomentofInteria)

 

I did but this error

Command: mmnt

Select Object:

Pick a Point: _.layer

Current layer: "0"

Enter an option

[Lee Mac]

Just using Larry's code:

 

(defun c:MMNT  (/ ent pt obj lst MNT)
 (vl-load-com)
 (if (and (setq ent (car (entsel "\nSelect Object: ")))
          (setq pt  (getpoint "\nPick a Point: ")))
   (progn
     (setq obj (vlax-ename->vla-object ent))
     (if (vlax-property-available-p obj 'MomentOfInertia)
       (progn 
         (setq lst (vlax-get obj 'MomentofInertia)
               MNT (strcat (rtos (car lst) 2 4) " " (rtos (cadr lst) 2 4)))
         
         (entmakex (list (cons 0 "TEXT")
                         (cons 10 pt)
                         (cons 40 (getvar "TEXTSIZE"))
                         (cons 1 MNT))))
       
       (princ "\n** Invalid Object Selected **"))))
   
 (princ))

[lpseifert]

You can avoid the variant with:

 

(vlax-get obj 'MomentofInteria)

Lee

I should've thought of that... I just read about that the other day at theSwamp. Much cleaner to avoid those dang variants when possible.

[Lee Mac]

I should've thought of that... I just read about that the other day at theSwamp. Much cleaner to avoid those dang variants when possible.

 

Yeah, its an undocumented function, but there are mixed results, as some functions don't work with the vlax-get/put

[rkmcswain]

LEE

 

I'll give a try and tell you

what shall I do is,

replace .... with .... I did but this error

 

Don't take this the wrong way, but rather than just replace bits of code with other bits of code without understanding what is happening, step through your code and get an understanding of what each function returns before passing that result to the next function, and so on.

[rkmcswain]

I should've thought of that...

 

Same here. I have used that before, but the syntax just didn't come to me at that moment...

 

Yeah, its an undocumented function, but there are mixed results, as some functions don't work with the vlax-get/put

 

Thanks again for the reminders...

[LEsq]

I should've thought of that... I just read about that the other day at theSwamp. Much cleaner to avoid those dang variants when possible.

 

It is a left over function from Vital Lisp - the original name of Visual Lisp.

[rkmcswain]

It is a left over function from Vital Lisp - the original name of Visual Lisp.

 

Ah yes... vital lisp....

http://www.allbusiness.com/technology/software-services-applications-programming/7022066-1.html

[LEsq]

Ah yes... vital lisp....

http://www.allbusiness.com/technology/software-services-applications-programming/7022066-1.html

 

Yep...

 

Now can be consider a vintage application

[Lee Mac]

Don't take this the wrong way, but rather than just replace bits of code with other bits of code without understanding what is happening, step through your code and get an understanding of what each function returns before passing that result to the next function, and so on.

 

I agree with this - you learn much better that way.