Rename command

[T704]

Hey folks, can someone plz help me, i was trying to use the rename command to subtract a prefix (from my layer names) and i am unable to figure it out or does someone know of a lisp file that would enable me to delete a prefix or ad a suffix, is there one out there? Appreciate any and all comments... Thanks buddies

[Lee Mac]

Quick 'n Dirty:

 

(defun c:DeleteLayerPrefix ( / p x n ) (vl-load-com)
 (if (< 1 (setq x (strlen (setq p (strcat (strcase (getstring t "\nSpecify Prefix: ")) "*")))))
   (vlax-for l (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
     (if (wcmatch (strcase (setq n (vla-get-name l))) p)
       (vl-catch-all-apply 'vla-put-name (list l (substr n x)))
     )
   )
 )
 (princ)
)

[T704]

Lee thanks will give it a quick spin. thanks once again

[T704]

Down and dirty gets the job done thanks, Lee !!

[Lee Mac]

Cool

 

A whole set...

 

(defun c:DeleteLayerPrefix ( / p x n ) (vl-load-com)
 (if (< 1 (setq x (strlen (setq p (strcat (strcase (getstring t "\nSpecify Prefix: ")) "*")))))
   (vlax-for l (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
     (if (wcmatch (strcase (setq n (vla-get-name l))) p)
       (vl-catch-all-apply 'vla-put-name (list l (substr n x)))
     )
   )
 )
 (princ)
)

(defun c:DeleteLayerSuffix ( / s x n ) (vl-load-com)
 (if (< 1 (setq x (strlen (setq s (strcat "*" (strcase (getstring t "\nSpecify Suffix: ")))))))
   (vlax-for l (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
     (if (wcmatch (strcase (setq n (vla-get-name l))) s)
       (vl-catch-all-apply 'vla-put-name (list l (substr n 1 (- (strlen n) x -1))))
     )
   )
 )
 (princ)
)

(defun c:AddLayerPrefix ( / p w n ) (vl-load-com)
 (setq p (getstring t "\nSpecify Prefix: ") w (strcat (strcase p) "*"))
 (vlax-for l (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
   (if (not (wcmatch (strcase (setq n (vla-get-name l))) w))
     (vl-catch-all-apply 'vla-put-name (list l (strcat p n)))
   )
 )
 (princ)
)

(defun c:AddLayerSuffix ( / s w n ) (vl-load-com)
 (setq s (getstring t "\nSpecify Suffix: ") w (strcat "*" (strcase s)))
 (vlax-for l (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
   (if (not (wcmatch (strcase (setq n (vla-get-name l))) w))
     (vl-catch-all-apply 'vla-put-name (list l (strcat n s)))
   )
 )
 (princ)
)

[T704]

Thanks Lee over and above thank you this will be part of my LEEMAC arsenal. much appreciated!