Call "pType" dialog over an active/loaded DCL window

[Costinbos77]

Hi ,

how will be possible by pressing a button , to call the command "pType" dialog , over an already active/loaded DCL window :

 

(command "'_pType")

 

Have an approach with Visual Lisp ?

 

In the next way ,

(action_Tile "myBut1" "(setq co1 \"1\") (vla-SendCommand (vla-Get-ActiveDocument (vlax-Get-Acad-Object)) \"'_pType\\r\")")

pType , will be executed , AFTER the lisp program will be finished .

 

Regards

Edited August 30, 2020 by Costinbos77

[Jonathan Handojo]

Use (setvar 'PDMODE <value>) instead of (command).

 

The values are described here. So as an example below:

 

(action_tile "myBut1" (vl-prin1-to-string '(progn (setq col "1") (setvar 'pdmode 3))))

 

Edited August 30, 2020 by Jonathan Handojo

[Costinbos77]

Yes , but it is nice the dialog , to select a shape of the point .

 

I know the next way as well :

(done_Dialog 10) ; close the existing dialog

(vl-cmdF "'_pType") ; my desire


; Restart the dialog

...
(start_Dialog)

....

 

Next one , is giving an error :

(action_Tile "myBut1" "(setq co1 \"1\") (done_Dialog 9) (vl-cmdf \"'_pType\\r\")")

 

Regards,

Edited August 30, 2020 by Costinbos77

[Jonathan Handojo]

Yes, there is a way, but how I know it is quite a bit advanced as such:

 

(while (not (vl-position flag '(0 1)))
    (if (new_dialog "your_dialog" your_loaded_dcl_file)
	(progn
	    
	    ;; all your DCL codes here (your action_tile, start_list, etc...)
	    ;; have the appropriate done_dialog numbers for the appropriate action_tiles
	    ;; The below is your desire
	    
	    (action_tile "myBut1" (vl-prin1-to-string '(progn (setq col "1") (done_dialog 10))))
	    
	    ;; After that, do the below:
	    
	    (setq flag (start_dialog))
	    
	    (cond
		
		((= flag 0) (alert "\nDialog cancelled") nil)
		
		((= flag 1)
		 ;; if code is accepted.
		 )
		
		((= flag 10) ; <-- your desire
		 (vl-cmdf "_ptype")
		 )
		
		((= flag <other_numbers>)
		 ;; more and more codes here
		 )
		
		)
	    )
	)
    )

 

Not sure if it's what you're after

Edited August 30, 2020 by Jonathan Handojo

[Costinbos77]

Yes , I am using that way , but I was thinking will be easy to load command "'_pType" dialog over my dialog . 

 

Not so lucky .

[BIGAL]

You can not open ptype over an existing dcl but you can make your own "ptype.dcl" as a child then it will allow you to set the values and remain in the parent dcl. Not sure where ptype dcl  source is might be one of them that you can find. 

 

Tried to find using "Point" may still be their somewhere will keep looking.

acad.dcl:            label = "Point is outside of boundary.";
acad.dcl:            label = "Point is directly on an object.";
acad.dcl:            label = "&Pick Points <";
acadmap.dcl:                label       = "&Prompt for Label Point" ;
acadmap.dcl:            label = "&Reference Insertion Point";
acadmap.dcl:   label = "Insertion Point";
acadmap.dcl:                label    = "&Point" ;
ade.dcl:                label   = "Point" ;
ade.dcl:        value = "Insert Point:";
ade.dcl:        label = "Use Insertion Point as Label Point";

 

As a side note Bricscad does not have a dcl for ptype.
 

Edited August 30, 2020 by BIGAL

[Costinbos77]

Briliant ideea BigAl , as usual ! Catch it !

 

So , I searched in the System partition , ALL the DCL files :

 

 

Then , I checked the keywords 'Point' or 'size' . ONLY few DCL files have this keywords , but none of them was related to command 'pType' , as was mentioned above .

 

I don't have 'ade.dcl' , instead I have 'ase.dcl' .

 

in conclusion :

 

1. maybe I didn't find ALL the DCL files ( improbable) ;

2. the command 'pType' is not using a DCL file / statement ;

3. the DCL is generic as : "button1" , "button2" ... "text1" "text2" .. "toggle1" "toggle2" ... and a lisp /software set the label/key of the Button / Text / toggle as : 'Point style' , 'Point size' , etc .

 

Was a greate ideea , but no success .

 

Regards ,

Edited August 31, 2020 by Costinbos77

[Roy_043]

Since the dialog shows an icon in the titlebar it is probably not DCL-based.

[eldon]

1 hour ago, Costinbos77 said:

............

1. maybe I didn't find ALL the DCL files ( improbable) ;

.......

 

Out of idle curiosity, I had a look in my Autodesk Support folder, and there was ddptype.dcl

 

 

[Costinbos77]

Hi eldon ,

 

I searched again , i dont have your files , please , can you share it ?

 

Edited August 31, 2020 by Costinbos77

[eldon]

I am surprised that it is apparently not still included, so beware in case it is version dependant!!

 

// Next available MSG number is     8 
// MODULE_ID DDPTYPE_DCL_
/* Next available MSG number is  17 */

//----------------------------------------------------------------------------
//
//     ddptype.dcl
//
//     Copyright 1992,1994,1996-1997 by Autodesk, Inc.
//
//     Permission to use, copy, modify, and distribute this software
//     for any purpose and without fee is hereby granted, provided
//     that the above copyright notice appears in all copies and
//     that both that copyright notice and the limited warranty and
//     restricted rights notice below appear in all supporting
//     documentation.
//
//     AUTODESK PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
//     AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
//     MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK, INC.
//     DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
//     UNINTERRUPTED OR ERROR FREE.
//
//     Use, duplication, or disclosure by the U.S. Government is subject to
//     restrictions set forth in FAR 52.227-19 (Commercial Computer
//     Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii)
//     (Rights in Technical Data and Computer Software), as applicable.
//
//.
//----------------------------------------------------------------------------
//
//  Ddptype.dcl - Point size and type selection dialogue.
//
//----------------------------------------------------------------------------

//  DDPTYPE dialogue.  Used by the DDPTYPE command in ddptype.lsp.
//  Called from the AutoCAD Release 12 Standard Menu.

//dcl_settings : default_dcl_settings { audit_level = 3; }

ddptype: dialog {
  label        = "Point Style";
  : column {
    : row {
      : image_button {
        key          = "pdmode0";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode1";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode2";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode3";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode4";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
    }
    : row {
      : image_button {
        key          = "pdmode32";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode33";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode34";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode35";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode36";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
    }
    : row {
      : image_button {
        key          = "pdmode64";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode65";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode66";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode67";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode68";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
    }
    : row {
      : image_button {
        key          = "pdmode96";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode97";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode98";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode99";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
      : image_button {
        key          = "pdmode100";
        width        = 5;
        aspect_ratio = 1.0;
        color        = 0;
        allow_accept = true;
      }
    }
  }
  : column {
    fixed_height = true;
    spacer_1;
    : row {
      : edit_box {
        mnemonic             = "S";
        label                = "Point Size:";
        key                  = "pdsize_value";
        edit_width           = 10;
        horizontal_alignment = left;
        allow_accept         = true;
      }
      : text {
        label = "";
        key   = "pdsize_label";
        width = 12;
      }
    }
    : radio_column {
      fixed_height = true;
      : radio_button {
        label       = "Set Size Relative to Screen";
        mnemonic    = "R";
        key         = "pdsize_r";
        is_tab_stop = false;
      }
      : radio_button {
        label       = "Set Size in Absolute Units";
        mnemonic    = "A";
        key         = "pdsize_a";
        is_tab_stop = false;
      }
    }
  }
  spacer_1;
  ok_cancel_help_errtile;
}

 

[Costinbos77]

Thanks eldon ,

 

it is a small difference in the arrangement of texts :

  

 

Please , can yoy specify from what version of AutoCAD is ?

 

Maybe the other fellows can specify if they finded or not in them AutoCAD version . Them help will be appreciated !

 

Regards ,

 

Costin

Edited August 31, 2020 by Costinbos77

[eldon]

1 hour ago, Costinbos77 said:

..........

Please , can you specify from what version of AutoCAD is ?

 

...........

 

 

I am using version 2002

[BIGAL]

Need ddptype.lsp as well please. Saves having to code the fill images.

 

It will be missing the images but these can be made with a simple loop making slides of the point style. These may be in a .SLB file maybe acad.slb

 

Makes sense that its part of an old version, Autodesk drop stuff in the re samples older versions had some good stuff for CIV3D.

 

For Jonathon need to incorporate the ddptype.dcl into your dcl then can call as a child dcl.

Example

(defun subdlg ()
  (setq dcl_id (load_dialog  "ddval"))
  (if (not (new_dialog "ddval" dcl_id))
  (exit))
  (action_tile "sizze" "(setq dimval (atof $value))(done_dialog)")
  (mode_tile "sizze" 3)
  (start_dialog)
)

 

Found the images in acad.slb so can read then from there.

 

Edited August 31, 2020 by BIGAL

[eldon]

As requested, here is the ddptype.lsp from my version of AutoCAD

 

; Next available MSG number is    11 
; MODULE_ID DDPTYPE_LSP_
;;;
;;;    ddptype.lsp
;;;
;;;    Copyright 1992,1994,1996-1998 by Autodesk, Inc.
;;;
;;;    Permission to use, copy, modify, and distribute this software
;;;    for any purpose and without fee is hereby granted, provided
;;;    that the above copyright notice appears in all copies and
;;;    that both that copyright notice and the limited warranty and
;;;    restricted rights notice below appear in all supporting
;;;    documentation.
;;;
;;;    AUTODESK PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
;;;    AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
;;;    MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK, INC.
;;;    DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
;;;    UNINTERRUPTED OR ERROR FREE.
;;;
;;;    Use, duplication, or disclosure by the U.S. Government is subject to
;;;    restrictions set forth in FAR 52.227-19 (Commercial Computer
;;;    Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii) 
;;;    (Rights in Technical Data and Computer Software), as applicable.
;;;
;;;.
;;;   C:DDPTYPE - set point style and size dialogue.
;;;
;;;               Uses ddptype.dcl for the dialogue definition.  The
;;;               slide images are in acad.slb.
;;;
;;; ===================== load-time error checking ============================
;;;

  (defun ai_abort (app msg)
     (defun *error* (s)
        (if old_error (setq *error* old_error))
        (princ)
     )
     (if msg
       (alert (strcat " Application error: "
                      app
                      " \n\n  "
                      msg
                      "  \n"
              )
       )
     )
     (exit)
  )

;;; Check to see if AI_UTILS is loaded, If not, try to find it,
;;; and then try to load it.
;;;
;;; If it can't be found or it can't be loaded, then abort the
;;; loading of this file immediately, preserving the (autoload)
;;; stub function.

  (cond
     (  (and ai_dcl (listp ai_dcl)))          ; it's already loaded.

     (  (not (findfile "ai_utils.lsp"))                     ; find it
        (ai_abort "DDPTYPE"
                  (strcat "Can't locate file AI_UTILS.LSP."
                          "\n Check support directory.")))

     (  (eq "failed" (load "ai_utils" "failed"))            ; load it
        (ai_abort "DDPTYPE" "Can't load file AI_UTILS.LSP"))
  )

  (if (not (ai_acadapp))               ; defined in AI_UTILS.LSP
      (ai_abort "DDPTYPE" nil)         ; a Nil <msg> supresses
  )                                    ; ai_abort's alert box dialog.

;;; ==================== end load-time operations ===========================

(defun ai_ptype_start ( / pt1 pt2 program)
  (setq ai_pts_lst '("0" "1" "2" "3" "4" "32" "33" "34" "35" "36"
                     "64" "65" "66" "67" "68" "96" "97" "98" "99" "100")
  )
  ;; Get program name
  (if (not (setq program (getvar "program")))
    (setq program "acad")
  )
  (foreach pt0 ai_pts_lst
    (setq pt1 (strcat "pdmode" pt0)
          pt2 (getvar "PDMODE")
    )
    (start_image pt1)
    (slide_image 
      0 0
      (- (dimx_tile pt1) 1) (- (dimy_tile pt1) 1) 
      (strcat program "(pt" pt0 ")")
    )
    (if (= pt2 (atoi pt0))
      (mode_tile pt1 2)
    )
    (end_image)
  )
)

(defun ai_ptype_set ()
  (ai_chk_pts nil)
  (if ai_pts_do
    (progn
      (if ai_pts0
        (setq ai_pts 0.0)
        (if (= (get_tile "pdsize_r") "1")
          (setq ai_pts (- 0.0 ai_pts))
        )
      )
      (setvar "PDSIZE" ai_pts)
      (setvar "PDMODE" (atoi (substr ai_ptmode 7 3)))
      (done_dialog 1)
    )
  )
)

(defun ai_chk_pts (pts0)
  (cond ((or (= ai_pts nil)
             (<= ai_pts 0.0)
         )
         (set_tile "error" "Invalid input.")
         (setq ai_pts_do nil)
     ; The next line was causing bug 80149.
         ;(mode_tile "pdsize_value" 2)
        )
        (T
         (set_tile "error" "")
         (setq ai_pts_do T)
         (if pts0
           (setq ai_pts0 nil)
         )
        )
  )
)

(defun ai_pdsize_r ()
  (if ai_pts
    (progn  
      (setq ai_pt_do T ai_pts0 nil ai_ptunt 2)
      (set_tile "pdsize_label" "%")
      (set_tile "pdsize_value" (rtos (setq ai_pts (abs ai_pts)) ai_ptunt))
    )
  )
)

(defun ai_pdsize_a ()
  (if ai_pts
    (progn
      (setq ai_pt_do T ai_pts0 nil ai_ptunt (getvar "LUNITS"))
      (if (or (= ai_ptunt 3)
              (= ai_ptunt 4)
          )
        (set_tile "pdsize_label" "")
        (set_tile "pdsize_label" "Units")
      )
      (set_tile "pdsize_value" (rtos (setq ai_pts (abs ai_pts)) ai_ptunt))
    )
  )
)

(defun ai_ptype_main (/ globals)
  (ai_ptype_start)
  (mode_tile ai_ptmode 4)
  (if (<= ai_pts 0.0)
    (progn
      (set_tile "pdsize_r" "1")
      (set_tile "pdsize_label" "%")
      (setq ai_ptunt 2)
    )
    (progn
      (set_tile "pdsize_a" "1")
      (setq ai_ptunt (getvar "LUNITS"))
      (if (or (= ai_ptunt 3)
              (= ai_ptunt 4)
          )
        (set_tile "pdsize_label" "")
        (set_tile "pdsize_label" "Units")
      )
    )
  )
  (set_tile "pdsize_value" (rtos (setq ai_pts (abs ai_pts)) ai_ptunt))
  (foreach pd0 ai_pts_lst
    (action_tile (strcat "pdmode" pd0) 
      "(mode_tile ai_ptmode 4)(setq ai_ptmode $key)(mode_tile ai_ptmode 4)"
    )
  )
  (action_tile "pdsize_value" "(setq ai_pts (distof $value)) (ai_chk_pts T)")
  (action_tile "pdsize_r" "(ai_pdsize_r)")
  (action_tile "pdsize_a" "(ai_pdsize_a)")
  (action_tile "accept" "(ai_ptype_set)")
  (action_tile "help" "(help \"\" \"ddptype\")")
  (start_dialog)
)

(defun c:ddptype (/ app dcl_id old_cmd ai_pts_do ai_ptmode ai_pts 
                    ai_pts0 undo_init ai_ptunt)

  ;; Set up error function.
  (setq old_cmd (getvar "cmdecho")    ; save current setting of cmdecho
        old_error  *error*            ; save current error function
        *error* ai_error              ; new error function
  )

  (setvar "cmdecho" 0)

  (cond
     (  (not (ai_trans)))                        ; transparent OK
     (  (not (ai_acadapp)))                      ; ACADAPP.EXP xloaded?
     (  (not (setq dcl_id (ai_dcl "ddptype"))))  ; is .DCL file loaded?
     (T 
        (if (/= 1 (logand (getvar "CMDACTIVE") 1)) (ai_undo_push))
        (ddptype_main)        
        (if (/= 1 (logand (getvar "CMDACTIVE") 1)) (ai_undo_pop))
     )                          ; proceed!
  )

  (setq *error* old_error) 
  (setvar "cmdecho" old_cmd)
  (princ)
)

(defun ddptype_main()
  (if (not (new_dialog "ddptype" dcl_id))
    (exit)
  )
  
  (setq ai_ptmode (strcat "pdmode" (itoa (getvar "PDMODE"))) 
        ai_pts (getvar "PDSIZE")
  )
  (setvar "CMDECHO" 0)
  (if (= ai_pts 0.0)
    (setq ai_pts -5.0 ai_pts0 T)
  )
  (ai_ptype_main)

  (princ)
)

(princ "  DDPTYPE loaded.  ")
(princ)

 

[Costinbos77]

Great staff hire , thanks gents !

 

1. The DCL file 'ddpType.dcl' can be hire : "C:\Program Files\Autodesk\AutoCAD 20XX\Support\ddpType.dcl" ;

 

or , with a small change , can be anyware :

...
; old
     (  (not (setq dcl_id (ai_DCL "ddptype")))) ; is .DCL file loaded?

; new
     (  (not (or (setq dcl_id (ai_DCL "ddptype")) (setq dcl_id (load_Dialog (strcat DCLpath "\\ddpType.dcl"))) )) ) ; is .DCL file loaded?
...

 

2. interesting tool 'AutoCAD Slide Library Manager' .

 

Regards,

[tombu]

This might be useful as an example anyway.

I played with a few Image Tile Menus many years ago even taught an ATP course in Spring 2003 for AUGI that covered Menu Customization. The VPORTS AutoCAD command uses an Image Tile Menu. They're loaded in the CUIX under Legacy (as in old way of doing things). Haven't messed with any since then.

//
//     Begin AutoCAD Image Menus
//
***image
**image_pdmode
[Point Mode]
[acad(pt0,dot)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 0)
[acad(pt32,dot+circle)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 32)
[acad(pt64,dot+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 64)
[acad(pt96,dot+circle+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 96)
[acad(pt1,blank)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 1)
[acad(pt33,circle)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 33)
[acad(pt65,box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 65)
[acad(pt97,circle+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 97)
[acad(pt2,plus)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 2)
[acad(pt34,plus+circle)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 34)
[acad(pt66,plus+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 66)
[acad(pt98,plus+circle+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 98)
[acad(pt3,multiply)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 3)
[acad(pt35,multiply+circle)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 35)
[acad(pt67,multiply+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 67)
[acad(pt99,multiply+circle+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 99)
[acad(pt4,tic)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 4)
[acad(pt36,tic+circle)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 36)
[acad(pt68,tic+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 68)
[acad(pt100,tic+circle+box)]^C^C^P(if(not Pnt_Style)(load "Pnt_Style"));(Pnt_Style 0.003 100)

Associated Lisp: 

;| POINTS OFF/ON SWITCH (WITHOUT REGEN!)
   BY: TOM BEAUFORD
   LEON COUNTY PUBLIC WORKS ENGINEERING SECTION

   This function takes two arguments Point Size & Point Mode.

==================================================================================|;
(defun Pnt_Style(pntsize pntmode / onoff count pnt_set set_length ent txt)
  (setvar "pdsize" pntsize)
  (setq onoff (getvar "pdmode") count 0)
  (if(= onoff pntmode)
       (setvar "pdmode" 1)
       (setvar "pdmode" pntmode)
  )
  (setq pnt_set (ssget "X" '((-4 . "<OR")(0 . "INSERT")(0 . "POINT")(-4 . "OR>"))))
  (if pnt_set (setq set_length (sslength pnt_set))(princ "No Points in Drawing!"))
  (while (< count set_length)
    (setq ent (ssname pnt_set count))
    (entupd ent)
    (setq count (1+ count))
  )
  (if(= onoff pntmode)
       (setq txt "Points Off!")
       (setq txt "Point Mode Set!")
  )
  (grtext -1 txt)
)

Slide Library attached

This allowed me to turn Points Off and On or change Mode without a regen which was slow back in the day.

acad.slb

[BIGAL]

Thanks Eldon DDptype lsp & DCL

 

Constinbos77 "C:\Program Files\Autodesk\AutoCAD 20XX\Support\ddpType.dcl" ;  not there CIV3D 2020. maybe only older versions.

 

Tombu Acad.slb is in "C:\Program Files\Autodesk\AutoCAD 20XX\Support\EN-US" ; or similar

 

Constinbos77 you will have to pull all the relevant bits out of DDptype.lsp and add to your lsp. So can open ptype as child dcl.

 

Edited September 1, 2020 by BIGAL

[Costinbos77]

Hi gents ,

 

1. Thank you very much Eldon for all the good stuff [ ddpType.dcl , ddpType.lsp ! Working excelent if the dcl it is in the right path  !

 

The image thing , looks interestig , I need to do some more research about it .

 

2. Thank you very much BigAl for your help / advices , are welcome and appreciated as always !

 

 

Regards ,

 

Costin

 

[BIGAL]

There are many dcl image examples out there I have 2x2 3x2 4x4 etc and just supply the "SLIDE" images to be displayed. useful for choices.