Extrude polylines based on numbers of inside

[tahta07 0]

 

 

Hello.
In my drawing, 
there are many blocks around and it says how many floors they are inside. 
I want to extrude these blocks. 
But since they are so numerous, it takes a long time to do it one by one. 
I'm looking for a lisp to extrude these blocks according to the numbers written in them.
It also works to select polylines based on the numbers inside
I'm sorry for my bad english.

http://prntscr.com/yz55au

 

Edited February 10 by tahta07

[BIGAL 588]

Post a dwg.

[tahta07 0]

here is the dwg

Drawing1.dwg

[tahta07 0]

6 hours ago, BIGAL said:

Post a dwg.

I posted

[ronjonp 248]

Here's a start:

(defun c:foo (/ i n p s sp)
  ;; RJP » 2021-02-12
  (if (setq s (ssget ":L" '((0 . "*POLYLINE"))))
    (progn (setq sp (vlax-ename->vla-object (cdr (assoc 330 (entget (ssname s 0))))))
	   (vl-cmdf "_.UNDO" "Be")
	   (setvar 'cmdecho 0)
	   (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
	     (setq p nil)
	     (repeat (fix (setq i (vlax-curve-getendparam e)))
	       (setq p (cons (vlax-curve-getpointatparam e i) p))
	       (setq i (1- i))
	     )
	     (if (and (setq i (ssget "_WP" p '((0 . "TEXT"))))
		      (> (setq n (atof (cdr (assoc 1 (entget (setq i (ssname i 0))))))) 0)
		 )
	       ;; Vl extrusion is not as editable?
	       (progn ;; (setq r (car (vlax-invoke sp 'addregion (list (vlax-ename->vla-object e)))))
		      ;; (vlax-invoke sp 'addextrudedsolid r (* 3 n) 0.)
		      (vl-catch-all-apply 'vl-cmdf (list "_.extrude" e "" (* 3 n)))
	       )
	     )
	   )
	   (vl-cmdf "_.UNDO" "End")
	   (setvar 'cmdecho 1)
    )
  )
  (princ)
)

 

[tahta07 0]

Thank you sir its work 

[ronjonp 248]

47 minutes ago, tahta07 said:

Thank you sir its work 

Glad to help