Request: Help changing ENTSEL code to SSGET

[ILoveMadoka]

I found and modified the code found here to create this

 

(defun C:EE1 (/ ent obj new_str)
  ;;; Add (E) to the end of a string
  (vl-load-com)
  (if (and (setq ent (car (entsel "\nSelect text object: ")))
           (wcmatch (cdadr (entget ent)) "*TEXT*")
           (setq obj (vlax-ename->vla-object ent))
           (setq new_str "(E)"))
    (progn
      (vla-put-textstring obj (strcat (vla-get-textstring obj) " " new_str))
      (princ "\nText updated successfully.")
    )
    (princ "\nInvalid selection or empty string.")
  )
  (princ)
)

 

which works on a single selected object.
Not sure how to create the repeat loop to process a selection set of TEXT/MTEXT objects.

 

 

 

[marko_ribar]

(defun C:EE1 (/ ss i obj new_str)
  ;;; Add (E) to the end of a string
  (vl-load-com)
  (if (and (not (prompt "\nSelect text objects on unlocked layer(s) : "))
           (setq ss (ssget "_:L" '((0 . "*TEXT*"))))
           (setq new_str "(E)"))
    (repeat (setq i (sslength ss))
      (setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
      (vla-put-textstring obj (strcat (vla-get-textstring obj) " " new_str))
      (princ "\nText updated successfully.")
    )
    (princ "\nInvalid selection or empty string.")
  )
  (princ)
)

 

Untested, but should work as desired...

HTH., M.R.

[ILoveMadoka]

Works perfectly..

Thank you so VERY much!!