How to show inch marks ( double quote ) after a decimal dimension?

[ILoveMadoka]

Solidworks 2023

How can I show inch marks after a decimal dimension?

 

these are "hand-jammed"

 

 

The closest I could figure out without having to manually change every dimension

 

 

gave me this

 

 

Is this possible?

Help please..

 

 

 

[ILoveMadoka]

In the help file

 

here

 

I came across this

 

 

I cannot find this in my settings anywhere...

 

ps: I want the " after the DECIMAL dimension  (24.25") 

Edited August 29, 2024 by ILoveMadoka

[BIGAL]

A dimension style can have a prefix and or a suffix so create a style with suffix ".

 

Edited August 30, 2024 by BIGAL

[ILoveMadoka]

I've looked all through my settings but cannot figure out how to create a dimension style in Solidworks.
I can get fractions to display with the inch mark but not decimal dimensions.

 

 

 

I appreciate your assistance Sir...

 

[SLW210]

I do not think it's possible IIRC.

 

Technically you don't put the " on decimal inches. If you look at the ASME and GD&T books, they don't use them on fractional either, more of an architectural and civil thing as far as I know.

 

AutoCAD and IIRC Inventor lets you add them.

 

Did you try the options when you click on a dimension?

[ILoveMadoka]

I wanted to avoid having to manually tweak every dimension...

People want Solidworks drawings to look like Autocad drawings...

 

[SLW210]

AutoCAD is pretty useful for custom solutions, particularly if you know basic toolbar buttons, menus, LISP et. al.

 

Most people like the look of manual drafting and AutoCAD easily adapts to what you are used to. Other software not so much.

 

I worked more on ProE drawings to make them look like what we had from manual drafting days and our AutoCAD drawings and per request from the client (that insisted on ProE) than I care to think about.

 

IIRC, it's been a long time since I used Soldworks, but select all dimensions and add " and save as favorites.

 

There may be some MACROs available on the DSS forums Login | 3DEXPERIENCE ID | Dassault Systèmes (3ds.com).

 

As long as I worked with Solidworks, it has been asked.

[mhupp]

Better late the never this will add a " to the end of dimensions for a drawing that is set to IPS. tho doesn't work quite right when tolerances are used.

 

 

will also prompt you if you are going to overwrite any data

 

 

 

Sub addtick()
  Dim swApp As SldWorks.SldWorks, swModel As SldWorks.ModelDoc2, swDraw As SldWorks.DrawingDoc
  Dim swView As SldWorks.View, swDispDim As SldWorks.DisplayDimension, swDim As SldWorks.Dimension
  Dim unitSystem As Long, okRun As Boolean, sCurrSuffix As String, id As String
  Set swApp = Application.SldWorks
  Set swModel = swApp.ActiveDoc
  If swModel Is Nothing Then
    MsgBox "No active document.", vbExclamation, "Add Inch Tick"
    Exit Sub
  End If
  If swModel.GetType <> swDocDRAWING Then
    MsgBox "This macro only runs on drawings.", vbExclamation, "Add Inch Tick"
    Exit Sub
  End If
  unitSystem = swModel.Extension.GetUserPreferenceInteger( _
                    swUserPreferenceIntegerValue_e.swUnitSystem, _
                    swUserPreferenceOption_e.swDetailingNoOptionSpecified)
  If unitSystem <> swUnitSystem_e.swUnitSystem_IPS Then
    MsgBox "This macro will only run in IPS(Inch, Pound, Second) Drawing.", vbExclamation, "Add Inch Tick"
    Exit Sub
  End If
  Set swDraw = swModel
  Set swView = swDraw.GetFirstView
  Do While Not swView Is Nothing
    Set swDispDim = swView.GetFirstDisplayDimension5
    Do While Not swDispDim Is Nothing
      Set swDim = swDispDim.GetDimension
      sCurrSuffix = swDispDim.GetText(swDimensionTextSuffix)
      If sCurrSuffix <> "" And Not sCurrSuffix = """" Then
        If MsgBox("Overwrite """ & sCurrSuffix & """?", vbQuestion + vbYesNo) = vbYes Then
          swDispDim.SetText swDimensionTextSuffix, """"
        End If
      Else
        swDispDim.SetText swDimensionTextSuffix, """"
      End If
      Set swDispDim = swDispDim.GetNext3
    Loop
    Set swView = swView.GetNextView
  Loop
  swModel.GraphicsRedraw2
  MsgBox "Ticks Added to Drawing"
End Sub