Copy and paste error (blocks changes!)

[X11start]

I made a stupid mistake and now I would like to find a way to avoid it: I copied a portion of a drawing (using CTRL+C) and pasted it into another (CTRL+V). The problem is that the copied part contained blocks that were already present with the same name in the new drawing. However, the blocks in the new drawing were slightly different.
Is it possible to create a lisp or something that warns: 'Attention: the drawing already contains blocks named XXXX'?

[GLAVCVS]

Perhaps someone knows a better way.
In my opinion, this could be done with reactors.
That is, in your AutoCAD session, there should be two latent reactors: one that activates after "copyclip" is executed and looks for the most recent DWG in the "temp" folder and saves its name in a global variable; and another that activates just before "pasteclip" is executed (:vlr-commandWillStart) and tracks the blocks of the DWG where the "copyclip" was created and the blocks of the current drawing.
There may already be a Lisp published in this forum that does this job, and some veteran can help you locate it.

[Nikon]

6 hours ago, X11start said:

Is it possible to create a lisp or something that warns: 'Attention: the drawing already contains blocks named XXXX'?

It would be nice to add a request along with the warning.:
(setq choice (getkword "[Continue/caNcel/Rename/Add-index-1] <Rename>: "))

Edited 5 hours ago by Nikon

[X11start]

Thank you very much, I also thought that the solution was to use Reactors... but creating a Lisp of this kind is way beyond my abilities! I hope that someone among the 'gurus' of this forum can help me. Thank you.

[Steven P]

Could do it with pure LISP rather than reactors, a new name though ("CopyWithBlocks" and "PasteWithBlocks" or something like that. CwB, PwB)

 

Weekend so CAD is off but something like this

Copy:

Select all the entities required in a selection set

Select the basepoint (or use a nominal one if necessary)

Loop through the selection set to find all the block names

Save this list as a variable - or if you want to be really clever - add this list to the copied information (never tried that but I think it is possible), perhaps as xdata in a point or something that can later be found and deleted

Copy to clipboard: (vl-cmdf "_.copyclip" basepoint MySS "")  (vl-cmdf "_.copybase" basepoint MySS "")

 

 

Paste:

Find the list of blocks from the xdata, and create a list of blocks in the target drawing

Compare the 2 lists and give any warnings necessary

If OK, paste. If not OK don't paste.

[rlx]

maybe something like this (untested)

 

;;; copy & paste for dummies - rlx 2025-10-18
(defun c:capfd ( / this-dwg ss other-dwg blocknames-in-selectionset blocknames-in-other-dwg duplicate-blocknames)
  (setq this-dwg (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (and (setq ss (ssget)) (setq other-dwg (getfiled "Copy SS to:" "" "dwg" 0)))
    (progn
      (setq blocknames-in-selectionset (Get_SS_BlockNames ss))
      (setq blocknames-in-other-dwg (Get_DBX_Blocknames other-dwg))
      (setq duplicate-blocknames (compare_block_names blocknames-in-selectionset blocknames-in-other-dwg))
      (if (vl-consp duplicate-blocknames)
        (progn
          (dplm duplicate-blocknames "Duplicated block names : ")
          (if (yes_no "Copy anyway?")
            (ctd ss other-dwg)
            (princ"\nBite me...")
          )
        )
        (ctd ss other-dwg)
      )
    )
  )
  (princ)
)

(defun compare_block_names (a b / c)
  (and (vl-consp a) (vl-consp b) (foreach item a (if (member item b) (setq c (cons item c))))) c)

(defun Get_SS_BlockNames ( ss / n l)
  (foreach o (ss->ol ss)
    (if (and (block-p o)(not (member (setq n (block-n o)) l))) (setq l (cons n l)))) l)

(defun SS->OL (ss / i l)(setq i 0)(repeat (sslength ss)(setq l (cons (vlax-ename->vla-object (ssname ss i)) l) i (1+ i))) l)

; (block-p (vlax-ename->vla-object (car (entsel))))
(defun block-p (o) (and (= 'vla-object (type O))(eq (vla-get-objectname O) "AcDbBlockReference")))

(defun block-n (o) (if (and (= 'vla-object (type O))(eq (vla-get-objectname O) "AcDbBlockReference"))
  (if (vlax-property-available-p o 'EffectiveName)(vla-Get-EffectiveName o)(vla-Get-Name o)) nil))

; (yes_no "Do you like snow")
(defun yes_no ( $m / f p i r ) (and (= (type $m) 'STR) (setq f (vl-filename-mktemp ".dcl")) (setq p (open f "w"))
  (write-line (strcat "yesno:dialog{label=\"" $m "?\";ok_cancel;}") p) (progn (close p)(gc) t) (setq i (load_dialog f))
    (new_dialog "yesno" i) (progn (action_tile "accept" "(done_dialog 1)")(action_tile "cancel" "(done_dialog 0)")
      (setq r (start_dialog))(unload_dialog i)(vl-file-delete f) t)(if (= r 1) t nil)))
     
;;; display list (plus message)
(defun dplm (l m / f p d w) (and (vl-consp l) (setq l (mapcar 'vl-princ-to-string l)) (setq w (+ 5 (apply 'max (mapcar 'strlen l))))
  (setq p (open (setq f (vl-filename-mktemp ".dcl")) "w")) (princ (strcat "cfl:dialog{label=\"" m "\";:list_box {key=\"lb\";"
   "width="(itoa w)";}ok_only;}") p)(not (setq p (close p)))(< 0 (setq d (load_dialog f)))(new_dialog "cfl" d)(progn (start_list "lb")
     (mapcar 'add_list l)(end_list)(action_tile "accept" "(done_dialog)")(start_dialog)(unload_dialog d)(vl-file-delete f))))


;;; copy to drawing
(defun ctd ( ss dwg / ss->ol dbx_ver acApp acDoc dbx object-list object-safe-array)  
  (defun SS->OL (ss / i l)
    (setq i 0)(repeat (sslength ss)(setq l (cons (vlax-ename->vla-object (ssname ss i)) l) i (1+ i))) l)
  (defun dbx_ver ( / v)
    (strcat "objectdbx.axdbdocument" (if (< (setq v (atoi (getvar 'acadver))) 16) "" (strcat "." (itoa v)))))
  (setq acApp (vlax-get-acad-object) acDoc (vla-get-ActiveDocument acApp))
  (setq dbx (vl-catch-all-apply 'vla-getinterfaceobject (list acApp (dbx_ver))))
  (vla-open dbx dwg)
  ; put all block objects in a list
  (setq object-list (ss->ol ss))
  ; put list with objects in a safe array
  (setq object-safe-array (vlax-make-safearray vlax-vbobject (cons 0 (1- (length object-list)))))
  (vl-catch-all-apply 'vlax-safearray-fill (list object-safe-array object-list))
  ; copy objects to dbx-drawing
  (vla-CopyObjects acDoc object-safe-array (vla-get-ModelSpace dbx))
  (vl-catch-all-apply 'vla-saveas (list dbx dwg))
  (vl-catch-all-apply 'vlax-release-object (list dbx))
  (setq object-list nil object-safe-array nil)
  (princ)
)

; test : (setq lst (GetDocBlockNames (vla-get-ActiveDocument (vlax-get-acad-object))))
; returns sorted list (uppercase) like : ("BLOCK_A" "BLOCK_B" ...)
(defun GetDocBlockNames (d / o n l)
  (vlax-for o (vla-get-blocks d)(if (and (= :vlax-false (vla-get-isxref o))(= :vlax-false (vla-get-islayout o))
    (snvalid (setq n (vla-get-name o)) 0))(setq l (cons (strcase n) l))))(if (vl-consp l)(acad_strlsort l)))

(defun Get_DBX_Blocknames ( doc-name / lst v objectdbx-document)
  (cond
    ((not (eq (type doc-name) 'STR))
     (princ (strcat "\nInvalid filename : " (vl-princ-to-string doc-name))))
    ((not (findfile doc-name))
     (princ (strcat "\nFile not found : " (vl-princ-to-string doc-name))))
    (t
     (vlax-for doc (vla-get-Documents (vlax-get-acad-object))
       (and (eq (strcase (vla-get-fullname doc)) (strcase doc-name))(setq objectdbx-document doc)))
     (cond
       ((eq (type objectdbx-document) 'VLA-OBJECT))
       ((not (setq objectdbx-document (vlax-create-object (strcat "objectdbx.axdbdocument"
	  (if (< (setq v (atoi (getvar 'acadver))) 16) "" (strcat "." (itoa v)))))))
	(princ "\nUnable to start object dbx"))
       ((vl-catch-all-error-p (vl-catch-all-apply 'vla-open (list objectdbx-document doc-name)))
        (princ (strcat "\nOdbx error - unable to acces : " doc-name)))
       (t (setq lst (GetDocBlockNames objectdbx-document)))
     )
     
    )
  )
  (vl-catch-all-apply 'vla-close (list objectdbx-document :vlax-False))
  (if (and (= 'vla-object (type objectdbx-document))(not (vlax-object-released-p objectdbx-document)))
    (vlax-release-object objectdbx-document))
  (if (vl-consp lst) (mapcar 'strcase lst))
)