Copy and paste error (blocks changes!)

[rlx]

You can try if this works better. No dbx in this version

 

Start app , make selection , select drawing you want to paste in later.

This drawing is shortly opened (not sure if it works if drawing is already open)

List with blocknames is created and drawing is closed.

 

Blocknames are compared and if duplicates are found message is displayed.

You can choose 1- Stop , 2 - Rename the blocks in drawing you made the selection set (not the other drawing), or 3 - copy / paste as it is.

 

Only thing left to do is select your basepoint (or replace 'pause' with "0,0" in the code) and selection set is placed on clipboard , ready to paste.

 

 

 

;;; check before paste - rlx 2025-10-22
(defun c:cbp ( / this-dwg ss other-dwg blocknames-in-selectionset blocknames-in-other-dwg duplicate-blocknames dbx-doc)
  (setq this-dwg (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (and (setq ss (ssget)) (setq other-dwg (getfiled "Drawing to check before you paste" "" "dwg" 0)))
    (progn
      (if (vl-consp (setq blocknames-in-selectionset (Get_SS_BlockNames ss)))
        (setq blocknames-in-selectionset (mapcar 'strcase blocknames-in-selectionset)))
      (if (vl-consp (setq blocknames-in-other-dwg (Get_EX_Blocknames other-dwg)))
        (setq blocknames-in-other-dwg (mapcar 'strcase blocknames-in-other-dwg)))
      (setq duplicate-blocknames (compare_block_names blocknames-in-selectionset blocknames-in-other-dwg))
      (if (vl-consp duplicate-blocknames)
        (progn
          (dplm duplicate-blocknames "Duplicated block names : ")
          (setq inp (cfl (list "1 - I'm not gonna paste" "2 - Rename blocks before pasting"  "3 - I'm gonna paste anyway")))
          (cond
            ((or (void inp) (wcmatch inp "1*")) (alert "Copybase aborted"))
            ((wcmatch inp "2*")(foreach b duplicate-blocknames (rename_block_definition b))
             (princ "\nBlocks are renamed - select your basepoint now") (command "_copybase" pause ss ""))
            ((wcmatch inp "3*")
             (princ "\nBlock names unchanged - select your basepoint now")(command "_copybase" pause ss ""))
            (t (princ"\nBite me..."))
          )
        )
        (progn (princ "\nNo duplicate block names found - select your basepoint")(command "_copybase" pause ss ""))
      )
    )
  )
  (princ)
)

;;; get block names active doc - vanilla
(defun _bl ( / b l ) (while (setq b (tblnext "BLOCK" (null b)))
  (if (zerop (boole 1 21 (cdr (assoc 70 b)))) (setq l (cons (cdr (assoc 2 b)) l)))) l)

(defun Get_EX_Blocknames (other-dwg / fn l)
  (if (and (eq (type other-dwg) 'STR)(setq fn (findfile other-dwg))
           (setq doc (vla-open (vla-get-documents (vlax-get-acad-object)) fn)))
    (progn (setq l (GetDocBlockNames doc))(vla-close doc)(vlax-release-object doc))) l)

;;; test (setq lst (GetDocBlockNames (vla-get-ActiveDocument (vlax-get-acad-object))))
(defun GetDocBlockNames ( d / b n l) (vlax-for b (vla-get-blocks d)
  (if (and (= :vlax-false (vla-get-isxref b)) (= :vlax-false (vla-get-islayout b))
    (not (vl-string-search "*" (setq n (vla-get-name b)))))(setq l (cons n l)))) l)

(defun create_unique_blockname ( $bn / i bn)
  (setq i 0)(while (tblsearch "block" (setq bn (strcat $bn "_" (itoa (setq i (1+ i))))))) bn)

(defun rename_block_definition ( $bn / bc bn )
  (setq bc (vla-get-blocks (vla-get-ActiveDocument (vlax-get-acad-object))))
  (if (and (not (void $bn)) (tblsearch "block" $bn))
    (vla-put-name (Collection-Member $bn bc)(setq bn (create_unique_blockname $bn)))) bn)

(defun compare_block_names (a b / c)
  (and (vl-consp a) (vl-consp b) (foreach item a (if (member item b) (setq c (cons item c))))) c)

(defun Get_SS_BlockNames ( ss / n l)
  (foreach o (ss->ol ss)(if (and (setq n (block-n o))(not (member n l)))(setq l (cons n l)))) l)

(defun SS->OL (ss / i l)(setq i 0)(repeat (sslength ss)(setq l (cons (vlax-ename->vla-object (ssname ss i)) l) i (1+ i))) l)

(defun void (x) (or (eq x nil)(and (listp x)(not (vl-consp x)))(and (eq 'STR (type x))(eq "" (vl-string-trim " \t\r\n" x)))))

(defun block-n (o)(if (and (= 'vla-object (type O))(eq (vla-get-objectname O) "AcDbBlockReference"))
  (if (vlax-property-available-p o 'EffectiveName) (vla-Get-EffectiveName o) (vla-Get-Name o)) nil))

(defun Collection-Member (m c / r)
  (if (vl-catch-all-error-p (setq r (vl-catch-all-apply 'vla-item (list c m)))) nil r))
  
;;; display list (plus message)
(defun dplm (l m / f p d w) (and (vl-consp l) (setq l (mapcar 'vl-princ-to-string l)) (setq w (+ 5 (apply 'max (mapcar 'strlen l))))
  (setq p (open (setq f (vl-filename-mktemp ".dcl")) "w")) (princ (strcat "cfl:dialog{label=\"" m "\";:list_box {key=\"lb\";"
   "width="(itoa w)";}ok_only;}") p)(not (setq p (close p)))(< 0 (setq d (load_dialog f)))(new_dialog "cfl" d)(progn (start_list "lb")
     (mapcar 'add_list l)(end_list)(action_tile "accept" "(done_dialog)")(start_dialog)(unload_dialog d)(vl-file-delete f))))

;; choose from list (cfl '("1""2""3"))
(defun cfl (l / f p d r) (and (setq p (open (setq f (vl-filename-mktemp ".dcl")) "w"))
 (princ "cfl:dialog{label=\"Choose\";:list_box{key=\"lb\";width=40;}ok_cancel;}" p)
  (not (setq p (close p)))(< 0 (setq d (load_dialog f)))(new_dialog "cfl" d)
   (progn (start_list "lb")(mapcar 'add_list l)(end_list)(action_tile "lb" "(setq r (nth (atoi $value) l))(done_dialog 1)")
    (action_tile "accept" "(setq r (get_tile \"lb\"))(done_dialog 1)")(action_tile "cancel" "(setq r nil)(done_dialog 0)")
     (start_dialog)(unload_dialog d)(vl-file-delete f))) (cond ((= r "") nil)(r r)(t nil)))

 

edit :

 

just had an idea , why not open the 'to be pasted' drawing after you made your selection.

 

Also tried if it was a bad thing if both drawings were already open and yes , that's  bad... but then I'm a bad bad dragon (it still opens but as read only)

 

Because I use vla-activate at the end , all lisp stops (obviously)

 

Once drawings is activated you can copypaste / ctrl-V yourself (I'm sure as hell not comming to do that for you  )

 

You decide what make you happy...

 

;;; check before paste 2 : after selection open the 'to be pasted' drawing - rlx 2025-10-22
(defun c:cbp2 ( / acDoc *docs* ss dbDoc blocknames-in-selectionset blocknames-in-dbDoc duplicate-blocknames inp do-it)
  (setq acDoc (vla-get-ActiveDocument (vlax-get-acad-object)) *docs* (vla-get-documents (vlax-get-acad-object)))
  (if (and (setq ss (ssget)) (setq dbDoc (getfiled "Drawing to check before you paste" "" "dwg" 0)))
    (progn
      (if (vl-consp (setq blocknames-in-selectionset (Get_SS_BlockNames ss)))
        (setq blocknames-in-selectionset (mapcar 'strcase blocknames-in-selectionset)))
      (if (vl-consp (setq blocknames-in-dbDoc (Get_EX_Blocknames dbDoc)))
        (setq blocknames-in-dbDoc (mapcar 'strcase blocknames-in-dbDoc)))
      (setq duplicate-blocknames (compare_block_names blocknames-in-selectionset blocknames-in-dbDoc))
      (if (vl-consp duplicate-blocknames)
        (progn
          (dplm duplicate-blocknames "Duplicated block names : ")
          (setq inp (cfl (list "1 - I'm not gonna paste" "2 - Rename blocks before pasting"  "3 - I'm gonna paste anyway")))
          (cond
            ((or (void inp) (wcmatch inp "1*")) (alert "Copybase aborted"))
            ((wcmatch inp "2*")(foreach b duplicate-blocknames (rename_block_definition b))
             (princ "\nBlocks are renamed - select your basepoint now")
             ;|(command "_copybase" pause ss "")|; (setq do-it t))
            ((wcmatch inp "3*")
             (princ "\nBlock names unchanged - select your basepoint now")
             ;|(command "_copybase" pause ss "")|; (setq do-it t))
            (t (princ"\nBite me..."))
          )
        )
        (progn
          (princ "\nNo duplicate block names found - select your basepoint")
          ;|(command "_copybase" pause ss "")|; (setq do-it t))
      )
    )
  )
  (if do-it (do_it))
)

(defun do_it ( / f d) (command "_copybase" pause ss "")(and (eq (type dbDoc) 'STR)
  (setq f (findfile dbDoc))(setq d (vla-open *docs* f)))(vla-activate d))
  

;;; get block names active doc - vanilla
(defun _bl ( / b l ) (while (setq b (tblnext "BLOCK" (null b)))
  (if (zerop (boole 1 21 (cdr (assoc 70 b)))) (setq l (cons (cdr (assoc 2 b)) l)))) l)

(defun Get_EX_Blocknames (dbDoc / fn l)
  (if (and (eq (type dbDoc) 'STR)(setq fn (findfile dbDoc))
           (setq doc (vla-open (vla-get-documents (vlax-get-acad-object)) fn)))
    (progn (setq l (GetDocBlockNames doc))(vla-close doc)(vlax-release-object doc))) l)

;;; test (setq lst (GetDocBlockNames (vla-get-ActiveDocument (vlax-get-acad-object))))
(defun GetDocBlockNames ( d / b n l) (vlax-for b (vla-get-blocks d)
  (if (and (= :vlax-false (vla-get-isxref b)) (= :vlax-false (vla-get-islayout b))
    (not (vl-string-search "*" (setq n (vla-get-name b)))))(setq l (cons n l)))) l)

(defun create_unique_blockname ( $bn / i bn)
  (setq i 0)(while (tblsearch "block" (setq bn (strcat $bn "_" (itoa (setq i (1+ i))))))) bn)

(defun rename_block_definition ( $bn / bc bn )
  (setq bc (vla-get-blocks (vla-get-ActiveDocument (vlax-get-acad-object))))
  (if (and (not (void $bn)) (tblsearch "block" $bn))
    (vla-put-name (Collection-Member $bn bc)(setq bn (create_unique_blockname $bn)))) bn)

(defun compare_block_names (a b / c)
  (and (vl-consp a) (vl-consp b) (foreach item a (if (member item b) (setq c (cons item c))))) c)

(defun Get_SS_BlockNames ( ss / n l)
  (foreach o (ss->ol ss)(if (and (setq n (block-n o))(not (member n l)))(setq l (cons n l)))) l)

(defun SS->OL (ss / i l)(setq i 0)(repeat (sslength ss)(setq l (cons (vlax-ename->vla-object (ssname ss i)) l) i (1+ i))) l)

(defun void (x) (or (eq x nil)(and (listp x)(not (vl-consp x)))(and (eq 'STR (type x))(eq "" (vl-string-trim " \t\r\n" x)))))

(defun block-n (o)(if (and (= 'vla-object (type O))(eq (vla-get-objectname O) "AcDbBlockReference"))
  (if (vlax-property-available-p o 'EffectiveName) (vla-Get-EffectiveName o) (vla-Get-Name o)) nil))

(defun Collection-Member (m c / r)
  (if (vl-catch-all-error-p (setq r (vl-catch-all-apply 'vla-item (list c m)))) nil r))
  
;;; display list (plus message)
(defun dplm (l m / f p d w) (and (vl-consp l) (setq l (mapcar 'vl-princ-to-string l)) (setq w (+ 5 (apply 'max (mapcar 'strlen l))))
  (setq p (open (setq f (vl-filename-mktemp ".dcl")) "w")) (princ (strcat "cfl:dialog{label=\"" m "\";:list_box {key=\"lb\";"
   "width="(itoa w)";}ok_only;}") p)(not (setq p (close p)))(< 0 (setq d (load_dialog f)))(new_dialog "cfl" d)(progn (start_list "lb")
     (mapcar 'add_list l)(end_list)(action_tile "accept" "(done_dialog)")(start_dialog)(unload_dialog d)(vl-file-delete f))))

;; choose from list (cfl '("1""2""3"))
(defun cfl (l / f p d r) (and (setq p (open (setq f (vl-filename-mktemp ".dcl")) "w"))
 (princ "cfl:dialog{label=\"Choose\";:list_box{key=\"lb\";width=40;}ok_cancel;}" p)
  (not (setq p (close p)))(< 0 (setq d (load_dialog f)))(new_dialog "cfl" d)
   (progn (start_list "lb")(mapcar 'add_list l)(end_list)(action_tile "lb" "(setq r (nth (atoi $value) l))(done_dialog 1)")
    (action_tile "accept" "(setq r (get_tile \"lb\"))(done_dialog 1)")(action_tile "cancel" "(setq r nil)(done_dialog 0)")
     (start_dialog)(unload_dialog d)(vl-file-delete f))) (cond ((= r "") nil)(r r)(t nil)))

 

Edited 12 hours ago by rlx

[X11start]

I created a pdf with all the steps: as expected by RLX, the lisp works perfectly!

 

'cbp2.lsp' can be used by those like me who use GStarCAD. Thank you very much!

CBP2.pdf

[rlx]

Youre welcome 

 

Only tweak I would probably do is to select your basepoint at the same time when you select your objects but that should be easy to do , but its not that importand anyways.

For now : paste away ...

 

[X11start]

Out of curiosity, since for me many of the commands you wrote are as understandable as ancient Aramaic:

which are the commands that you didn't include in the latest version... and that allowed Lisp to work even on GSTARCAD?

[SLW210]

What version of GstarCAD are you using?

 

Enhanced API in GstarCAD 2024

 

I would think anything that runs in AutoCAD LT would work, if I have time and @rlx doesn't get back, I'll try to look at them (I am curious about this).

 

If you could carefully list out what happened with each code in AutoCAD and GstarCAD, it would help.

[rlx]

in essence I took out the dbx stuf like :

(defun dbx_ver ( / v)
    (strcat "objectdbx.axdbdocument" (if (< (setq v (atoi (getvar 'acadver))) 16) "" (strcat "." (itoa v)))))
  (setq acApp (vlax-get-acad-object) acDoc (vla-get-ActiveDocument acApp))
  (setq dbx (vl-catch-all-apply 'vla-getinterfaceobject (list acApp (dbx_ver))))
  (vla-open dbx dwg)
  ; put all block objects in a list
  (setq object-list (ss->ol ss))
  ; put list with objects in a safe array
  (setq object-safe-array (vlax-make-safearray vlax-vbobject (cons 0 (1- (length object-list)))))
  (vl-catch-all-apply 'vlax-safearray-fill (list object-safe-array object-list))
  ; copy objects to dbx-drawing
  (vla-CopyObjects acDoc object-safe-array (vla-get-ModelSpace dbx))
  (vl-catch-all-apply 'vla-saveas (list dbx dwg))
  (vl-catch-all-apply 'vlax-release-object (list dbx))
  (setq object-list nil object-safe-array nil)

 In lasted version I used : 

(defun Get_EX_Blocknames (dbDoc / fn l)
  (if (and (eq (type dbDoc) 'STR)(setq fn (findfile dbDoc))
           (setq doc (vla-open (vla-get-documents (vlax-get-acad-object)) fn)))
    (progn (setq l (GetDocBlockNames doc))(vla-close doc)(vlax-release-object doc))) l)

;;; test (setq lst (GetDocBlockNames (vla-get-ActiveDocument (vlax-get-acad-object))))
(defun GetDocBlockNames ( d / b n l) (vlax-for b (vla-get-blocks d)
  (if (and (= :vlax-false (vla-get-isxref b)) (= :vlax-false (vla-get-islayout b))
    (not (vl-string-search "*" (setq n (vla-get-name b)))))(setq l (cons n l)))) l)

 

instead of using (vla-open dbx dwg) I now used (vla-open (vla-get-documents (vlax-get-acad-object)) fn)

 

using vla-open means you best only use vla- commands and never ever use vla-activate until the very last end because at that point lisp focus will end there and any code left with it. Lisp can only run in one document at the time , but when using vla- commands only it is possible to open and close other drawing and stil maintain lisp focus. Maybe not beginners stuf but me too only got where I am by beg steal & borrow code from others , change things an see what happens. This all costs time but having a wife with her own hobbies or not having a social life all helps 

 

[SLW210]

After a quick look on GstarCAD, DBX works, though some commands may be different from AutoCAD's.

 

If time allows I might make an attempt to narrow down some options.