The coordinates of the trapezoid

[Vica]

Hi

Thank you all for these codes.

However, I think this tool would be much better if the trapezoid angle could be adjusted interactively. It's often necessary to make adjustments to adapt it to the elements of the drawing.

[Vica]

 

1 hour ago, Vica said:

Hi

Thank you all for these codes.

However, I think this tool would be much better if the trapezoid angle could be adjusted interactively. It's often necessary to make adjustments to adapt it to the elements of the drawing.

I mean that one side of the trapezoid must usually be irregular.

[mhupp]

7 hours ago, Vica said:

I think this tool would be much better if...

 

These lisp's are to draw a trapezoid. I don't know if adding more features makes this completed code better. Id would have a separate code to make the irregular trapezoid and a main function to ask what shape you want to make. as far as dynamic mode modifying the poly in the drawing nothing more dynamic then that. this creates more options by call the irregular trapezoid lisp by itself or from a main list. you can even add other shapes to the main lisp.

 

;;----------------------------------------------------------------------------;;
;; All-Shapes or AS creates a DCL menu to pick what shape you want to create
;; and runs sub lisp of option picked
;; https://www.cadtutor.net/forum/topic/98827-the-coordinates-of-the-trapezoid/
(defun C:AS () (C:ALL-Shapes))
(defun C:All-Shapes (/ shplst shp)
  (setq shplst (list  "Trapezoid" "Irregular Trapezoid" "Circle"))
  (setq shp (nth (ahlstbox "Pick a Shape" shplst  20 10) shplst))
  (cond
    ((= shp "Trapezoid")(C:Trapezoid))
    ((= shp "Irregular Trapezoid")(C:IrrTrapezoid))
    ((= shp "Circle")(C:Cir))
  )
)
;; code by pkenewell
(defun C:Trapezoid (/ bw p0 p1 p2 p3 p4 ra sa th)
   (if
      (and
         (setq bw (getreal "\nEnter the width of the Base: ")
               th (getreal "\nEnter the Height: ")
               sa (getreal "\nEnter the side angles: ")
               p0 (getpoint "\nSelect the insertion point: ")
		 )
      )
      (progn
         (setq ra (* pi (/ sa 180.0))
               p1 (list (- (car p0) (/ bw 2)) (cadr p0) (caddr p0))
               p2 (list (+ (car p1) bw) (cadr p0) (caddr p0))
               p3 (list (+ (car p2) (* (/ th (cos ra)) (sin ra))) (+ (cadr p0) th) (caddr p0))
               p4 (list (- (car p1) (* (/ th (cos ra)) (sin ra))) (+ (cadr p0) th) (caddr p0))
         )
         (entmakex
            (append
                (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline") '(90 . 4) '(70 . 1))
                (mapcar '(lambda (x) (cons 10 x)) (list p1 p2 p3 p4))
            )
         )
      )
   )
)
(defun C:IrrTrapezoid (/ bw p0 p1 p2 p3 p4 ra sa th)
  (alert "Code Needed for Irregular Trapezoid")
  (princ)
)
(defun C:Cir ()
  (while (setq p (getpoint "\nSelect Point Center of Circle: "))
    (command "_.CIRCLE" p pause)
  )
)
; listbox-ah a library lst box routine pick just one from 
; By Alan H March 2019
; (if (not AHlstbox)(load "Listbox-AH.lsp"))
;(setq ans (ahlstbox "Pick a number" (list "150" "200" "225" "250" "300" "375" "450" "600") 20 10))
; ans is returned as item number selected of the list
(defun AHlstbox (heading lst wid ht / fo fname lsec )
  (setq fo (open (setq fname (vl-filename-mktemp "" "" ".dcl")) "w"))
  (write-line "AHlstbox : dialog {" fo)
  (write-line   (strcat " label = " (chr 34) heading (chr 34)  "  ;" )   fo)
  (write-line   "    spacer  ; " fo)
  (write-line   "    :list_box { " fo)
  (write-line (strcat " key=" (chr 34) "lst" (chr 34) " ; ") fo)
  (write-line  (strcat "    multiple_select=" (chr 34) "false" (chr 34)  " ; ") fo)
  (write-line   (strcat "    width= " (rtos wid 2 0) " ; ") fo)
  (write-line   (strcat "    height=" (rtos ht 2 0 ) " ; ") fo)
  (write-line   "    }   " fo)
  (write-line   "spacer ;" fo)
  (write-line    "   ok_cancel ; " fo)
  (write-line "  } " fo)
  (close fo)
  (setq dcl_id (load_dialog fname))
  (if (not (new_dialog "AHlstbox" dcl_id))
    (exit)
  )
  (start_list "lst")
  (foreach itm lst (add_list itm))
  (end_list)
  (action_tile "lst" "(setq lsec (atoi $value) )")
  (start_dialog)
  (unload_dialog dcl_id)
  (vl-file-delete fname)
  (princ lsec)
)

 

Edited 12 hours ago by mhupp

[Tsuky]

For fun, an another old code (in French)

trapeze_dyn.lsp

[BIGAL]

My $0.05 you can draw any shape you want wether it be some form of trapezoid or a shape with 30 sides. It just comes down to writing code that matches the desired shape,

 

Normal trapezoid length, height, angle

Dbl angle length, height, angle1, angle2

Indented length, height, angle1, angle2, angle3

 

And so on., just ask which one you want first.

 

You can even pop a image choice of what you want. Don't have trapezoids as images.

 

Then for me pop a dcl for matching input.

 

Ps @mhupp you don't have to put the AHlstbox in the code can use

 

if (not ahlstbox)(Load "ahlstbox.lsp")) ; will load lisp code on the fly if not already loaded.

 

Edited 7 hours ago by BIGAL

[mhupp]

Yea was thinking something like this.

https://www.cadtutor.net/forum/topic/61373-need-help-with-proper-spacing-in-a-dialog-box/#findComment-506754

[BIGAL]

Yeah Lee's code is brilliant as usual. Nice way the image changes. 

 

Two things,

 

Use Rlx convert DCL to lsp so dcl code is in lisp.

 

Quote

Using vector images within DCL (Dialog Control Language) in AutoLISP involves drawing lines and filled shapes directly within an image tile in a DCL dialog box. This is distinct from inserting raster images or AutoCAD slides.

 

 Will have a think about vectors have some code some where.Convert dcl 2 lisp rlx.lsp

Edited 3 hours ago by BIGAL

[BIGAL]

I made some simple shapes and used Vectorize to do just that, here are some samples. next step is to look at Lee-Mac example. Only read the vectors pattern in the following code.

 

;********************************************************************************
; Function to draw a vector image within a dialogue Image tile or Image Button. *
; Argument:   'DCLKEY' - the dcl key of the image tile/button to be filled.     *
;    Do NOT edit the dcl dimension text below, this is needed by Vectorize.     *
;********************************************************************************
; Compiled for dcl dimensions of width,24.92, height,24.97,                     *
;********************************************************************************
(defun VECTOR1 (DCLKEY / i j)
  (setq i (/ (dimx_tile DCLKEY) 151.) j (/ (dimy_tile DCLKEY) 326.))
  (start_image DCLKEY)
  (fill_image 0 0 (dimx_tile DCLKEY)(dimy_tile DCLKEY) -15)
  (foreach x '((19 222 128 222 7) (128 222 128 114 7) (128 114 19 114 7) (19 114 19 222 7))
  (vector_image (fix (* (car x) i))(fix (* (cadr x) j))(fix (* (caddr x) i))(fix (* (cadddr x) j))(last x)))
  (end_image)
  (princ)
)
(defun VECTOR2 (DCLKEY / i j)
  (setq i (/ (dimx_tile DCLKEY) 151.) j (/ (dimy_tile DCLKEY) 326.))
  (start_image DCLKEY)
  (fill_image 0 0 (dimx_tile DCLKEY)(dimy_tile DCLKEY) -15)
  (foreach x '((37 202 119 202 7) (119 202 139 120 7) (139 120 17 120 7) (17 120 37 202 7))
  (vector_image (fix (* (car x) i))(fix (* (cadr x) j))(fix (* (caddr x) i))(fix (* (cadddr x) j))(last x)))
  (end_image)
  (princ)
)
(defun VECTOR3 (DCLKEY / i j)
  (setq i (/ (dimx_tile DCLKEY) 151.) j (/ (dimy_tile DCLKEY) 326.))
  (start_image DCLKEY)
  (fill_image 0 0 (dimx_tile DCLKEY)(dimy_tile DCLKEY) -15)
  (foreach x '((36 203 120 203 7) (120 203 101 161 7) (141 119 16 119 7) (16 119 36 203 7) (101 161 141 119 7))
  (vector_image (fix (* (car x) i))(fix (* (cadr x) j))(fix (* (caddr x) i))(fix (* (cadddr x) j))(last x)))
  (end_image)
  (princ)
)
(defun VECTOR4 (DCLKEY / i j)
  (setq i (/ (dimx_tile DCLKEY) 151.) j (/ (dimy_tile DCLKEY) 326.))
  (start_image DCLKEY)
  (fill_image 0 0 (dimx_tile DCLKEY)(dimy_tile DCLKEY) -15)
  (foreach x '((38 200 118 200 7) (118 200 99 160 7) (138 120 18 120 7) (55 168 38 200 7) (99 160 138 120 7) (55 168 18 120 7))
  (vector_image (fix (* (car x) i))(fix (* (cadr x) j))(fix (* (caddr x) i))(fix (* (cadddr x) j))(last x)))
  (end_image)
  (princ)
)

 

(setq imgslst (list 
(list (list 19 222 128 222 7) (list 128 222 128 114 7) (list 128 114 19 114 7) (list 19 114 19 222 7))
(list (list 37 202 119 202 7) (list 119 202 139 120 7) (list 139 120 17 120 7) (list 17 120 37 202 7))
(list (list 36 203 120 203 7) (list 120 203 101 161 7) (list 141 119 16 119 7) (list 16 119 36 203 7)(list 101 161 141 119 7))
(list (list 38 200 118 200 7) (list 118 200 99 160 7) (list 138 120 18 120 7) (list 55 168 38 200 7)(list 99 160 138 120 7)(list 55 168 18 120 7))
)
)

Watch this psace.

 

VECTORIZE.lsp

Edited 2 hours ago by BIGAL

[BIGAL]

This is a very simple test to make everything is inside the code including the images. next step would be to look at the Lee-mac example and use vectors rather than slides. Thanks to RLX for convert DCL.

 

 

; https://www.cadtutor.net/forum/topic/98827-the-coordinates-of-the-trapezoid/page/2/#comment-677242
; Fill in 4 image dcl with vector images
; simple working example by AlanH Nov 2025

(setq imgslst (list 
(list (list 19 222 128 222 7) (list 128 222 128 114 7) (list 128 114 19 114 7) (list 19 114 19 222 7))
(list (list 37 202 119 202 7) (list 119 202 139 120 7) (list 139 120 17 120 7) (list 17 120 37 202 7))
(list (list 36 203 120 203 7) (list 120 203 101 161 7) (list 141 119 16 119 7) (list 16 119 36 203 7)(list 101 161 141 119 7))
(list (list 38 200 118 200 7) (list 118 200 99 160 7) (list 138 120 18 120 7) (list 55 168 38 200 7)(list 99 160 138 120 7)(list 55 168 18 120 7))
)
)


(defun VECTOR4 (dclkey imglst / i j)
  (setq i (/ (dimx_tile DCLKEY) 151.) j (/ (dimy_tile DCLKEY) 326.))
  (start_image DCLKEY)
  (fill_image 0 0 (dimx_tile DCLKEY)(dimy_tile DCLKEY) -2)
  (foreach x imglst
    (vector_image (fix (* (car x) i))(fix (* (cadr x) j))(fix (* (caddr x) i))(fix (* (cadddr x) j))(last x))
  )
  (end_image)
  (princ)
)

(defun makedcl ( / )
(setq dcl (vl-filename-mktemp nil nil ".dcl") )
(setq des (open dcl "w") )
(foreach x 
'(
"//  dd2x2 dialogue.  Used by the d2x2 command in dd2x2.lsp."
"//  Called from the AutoCAD Release 12 Standard Menu."

"dd2x2: dialog {"
"  label        = \"Pick shape\";"
"  : column {"
"    : row {"
"      : image_button {"
"        key          = \"22sq1\";"
"        width        = 15;"
"        aspect_ratio = 1.0;"
"        color        = 0;"
"        allow_accept = true;"
"      }"
"      : image_button {"
"        key          = \"22sq2\";"
"        width        = 15;"
"        aspect_ratio = 1.0;"
"        color        = 0;"
"        allow_accept = true;"
"      }"
"      }"
"    : row {"
"      : image_button {"
"        key          = \"22sq3\";"
"        width        = 15;"
"        aspect_ratio = 1.0;"
"        color        = 0;"
"        allow_accept = true;"
"      }"
"      : image_button {"
"        key          = \"22sq4\";"
"        width        = 15;"
"        aspect_ratio = 1.0;"
"        color        = 0;"
"        allow_accept = true;"
"      }"
"      }"
"  }"
"ok_cancel;"
"}"
)
(write-line x des )
); foreach
(close des)
(princ)
)

(defun wow ( / x ans dcl keynum imgsitem dclkey )
  (makedcl)
  (setq dcl_id (load_dialog dcl))
  (if (not (new_dialog "dd2x2" dcl_id) )
   (exit)
  )
  (setq keynum 1)
  (repeat 4
    (setq imgsitem (nth (- keynum 1) imgslst))
    (setq dclkey (strcat "22sq" (rtos keynum 2 0)))
    (VECTOR4 dclkey imgsitem)
    (setq keynum (1+ keynum))
  )
  
  (action_tile "22sq1" "(setq ans $key)(done_dialog)")
  (action_tile "22sq2" "(setq ans $key)(done_dialog)")
  (action_tile "22sq3" "(setq ans $key)(done_dialog)")
  (action_tile "22sq4" "(setq ans $key)(done_dialog)")
  (action_tile "accept" "(setq ans $key)(done_dialog)")
  (action_tile "cancel" "(setq ans $key)(done_dialog)")
  
  (start_dialog)
  (unload_dialog dcl_id)
  (vl-file-delete dcl)
  
  (princ (strcat "\nsq picked = " ans))
  (princ)
)

(wow)